Créer un service avec Automator - Testé sur MacOS Sierra

1. Ouvrir /Applications/Automator.app
2. Fichier > Nouveau (cmd-N)
   • Choisissez un type de document : "Service".
3. Service reçoit sélectionné : "fichiers ou dossiers" dans "Finder".
4. Dans le volet de gauche, naviguez vers : Actions > Bibliothèque > Utilitaires > Exécuter AppleScript.
   • Faites glisser l'élément "Exécuter AppleScript" du volet de la bibliothèque, à gauche, vers le volet du code source, à droite.
5. Effacer entièrement le contenu pré-rempli. Collez le code source suivant :

Code source AppleScript

use framework "Foundation" -- Cocoa-AppleScript

on run {input, parameters}
    repeat with thisItem in input
        tell application "Finder"
            if kind of thisItem is "Alias" then -- alias file only
                set parentPath to container of thisItem -- get the folder of this alias
                set {label index:l, comment:c, modification date:m, creation date:cr, original item:origPath, name:n} to properties of (item thisItem)
                if origPath is not missing value then -- not a breaking alias
                    set tagsList to (my tagsFor:(POSIX path of thisItem)) -- get the tags of the alias file (call an AppleScriptObjC handler)
                    delete thisItem -- move this alias to the trash

                    -- ** create an alias file **
                    set newAliasFile to make new alias at parentPath to origPath with properties {comment:c, creation date:cr, original item:origPath, name:n}
                    -- ** set the label ** (0 = no label)
                    if l is not 0 then set label index of newAliasFile to l
                    -- ** set  the tags ** ({} = no tag) 
                    if tagsList is not {} then (my setTags:tagsList forPath:(POSIX path of (newAliasFile as string))) -- call an AppleScriptObjC handler
                    -- ** change the modification date **
                    set modification date of newAliasFile to m
                end if
            end if
        end tell
    end repeat
end run

on tagsFor:posixPath -- Cocoa-AppleScript handler 
    set fileURL to current application's |NSURL|'s fileURLWithPath:posixPath
    set {theResult, theTags} to fileURL's getResourceValue:(reference) forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
    if theTags = missing value then return {} -- no tags
    return theTags as list
end tagsFor:

on setTags:tagList forPath:posixPath -- Cocoa-AppleScript handler
    set fileURL to current application's |NSURL|'s fileURLWithPath:posixPath
    fileURL's setResourceValue:tagList forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
end setTags:forPath:

6. Fichier > Enregistrer (cmd-S) : Donnez-lui un nom comme "Alias récréation".
7. Ouvrez Préférences Système > Clavier > Raccourcis > Services > Fichiers et dossiers > Alias de récréation, ou tout autre nom que vous lui avez donné.
   • Attribuez-lui un raccourci. Comme cmd-L est utilisé pour créer un alias (L comme dans "link"), je lui ai attribué cmd-alt-ctrl-L.
8. Sélectionnez un ou plusieurs fichiers d'alias anciens, et traitez-les.
   • Avec votre raccourci cmd-alt-ctrl-L.
   • ou par le biais du menu principal : Finder > Services > Fichiers et dossiers > Alias de récréation.

Note : Le processus de lot est très transparent et les erreurs peuvent être corrigées. Les alias supprimés sont déplacés dans votre corbeille. Si vous avez fait une erreur, choisissez le fichier alias supprimé en question et exécutez Finder > Put back (cmd-backspace). Ceci remettra le fichier dans son ancien dossier parent et ouvrira le dossier parent dans une nouvelle fenêtre. Vous avez alors côte à côte l'alias recréé et l'alias original avec le suffixe " copy " et vous pouvez faire des corrections si nécessaire.