Lors de l'ouverture d'un fichier DMG, comment puis-je le faire s'ouvrir devant les fenêtres?

J'ai créé un script d'Action de Dossier en Applescript, qui pourrait faire exactement ce que vous voulez. Copiez et collez-le dans un nouvel Applescript, et enregistrez-le en tant qu'Application (sans dialogue de démarrage !) dans "/Library/Scripts/Folder Action Scripts/". Vous pouvez ensuite le joindre à n'importe quel dossier (probablement votre dossier ~/Téléchargements/) en cliquant avec le bouton droit sur le dossier et en sélectionnant "configurer les actions de dossier" dans le menu déroulant des services. Activez les Actions de Dossier et laissez le script surveiller le dossier.

Ce que fait essentiellement le script, c'est réagir aux éléments déposés dans le dossier auquel il est attaché et si l'élément déposé est de type : "Disk Image", il attache l'Image en tant que Volume via l'outil en ligne de commande "hdiutil".

Vous pouvez configurer son comportement en réglant les propriétés openWindow et makeFrontmost dans le Script ; cela peut également être fait en double-cliquant sur le Script après l'avoir enregistré en tant qu'application - il demandera ensuite dans deux dialogues quelle devrait être sa comportement standard.

J'espère que cela vous aidera,

Asmus

 property openWindow : true
 property makeFrontmost : true

 on run

    display dialog "Voulez-vous mettre le Finder au premier plan après l'ajout de nouveaux éléments ?" buttons {"Ne pas activer", "Activer"} default button 2
    if the button returned of the result is "Ne pas activer" then
        set makeFrontmost to false
    else
        set makeFrontmost to true
    end if

    display dialog "Ouvrir le dossier après l'ajout de nouveaux fichiers ?" buttons {"Ne pas ouvrir", "Ouvrir"} default button 2
    if the button returned of the result is "Ne pas ouvrir" then
        set openWindow to false
    else
        set openWindow to true
    end if

 end run

 on adding folder items to thisFolder after receiving addedItems

    repeat with i from 1 to number of items in addedItems
        set itemKind to the kind of (info for item i of addedItems) as string

        if itemKind is "Disk Image" then
            set itemPath to (quoted form of POSIX path of item i of addedItems)
            try
                showImage(itemPath)
            end try
        end if

    end repeat

 end adding folder items to

 on showImage(itemPath)

    set volumeMountpointInfo to do shell script "/usr/bin/hdiutil  attach " & itemPath & " | grep Volumes"

    if (openWindow is true) then
        if (makeFrontmost is true) then
            tell application "Finder" to activate
        end if

       set currentDelim to text item delimiters
       set text item delimiters to tab

       set volumeMountpoint to POSIX file (text item 3 of volumeMountpointInfo)

       set text item delimiters to currentDelim

       tell application "Finder" to open folder volumeMountpoint

    end if

 end showImage

\====

second Applescript pour déterminer le type de fichier déposé dans un dossier

On adding folder items to thisFolder after receiving addedItems
repeat with i from 1 to number of items in addedItems
    set itemKind to the kind of (info for item i of addedItems) as string
    display dialog itemKind
end repeat
end adding folder items to

Édité Doit être "Disk Image" au lieu de "Image"