Comportement différent des catégories dans l'interface graphique et dans AppleScript

J'ai eu exactement le même problème. J'ai pu le résoudre en appliquant l'identifiant exact de la catégorie que je voulais :

set end of theList to category id 33

Plutôt que comme :

set end of theList to category "Category1"

Voici comment j'ai obtenu les identifiants des catégories. J'ai sélectionné un message dans Outlook qui avait uniquement la catégorie que je voulais, puis j'ai exécuté ce script manuellement à partir de l'éditeur script :

tell application "Microsoft Outlook"

    set msgSet to current messages
    if msgSet = {} then
        error "No messages selected. Select at least one message."
        error -128
    end if

    repeat with aMessage in msgSet
        set theList to categories of aMessage
        return theList
    end repeat

end tell

J'ai ensuite utilisé l'identifiant de catégorie renvoyé dans le code ci-dessous pour définir les messages de cette catégorie à l'avenir (j'ai bricolé cela à partir de nombreuses sources en ligne au fil du temps, il n'est donc malheureusement pas facile pour moi de donner du crédit aux bonnes personnes) :

tell application "Microsoft Outlook"

    -- Workaround for Outlook 2016 Reminders window bug, part 1
    set windowClosed to false
    if "Reminder" is in (name of the front window) then
        set windowClosed to true
        close front window
    end if

    set msgSet to current messages
    if msgSet = {} then
        error "No messages selected. Select at least one message."
        error -128
    end if

    repeat with aMessage in msgSet          
        set theList to categories of aMessage
        set end of theList to category id 33 -- CHANGE THIS TO THE CATEGORY ID RETURNED IN THE PREVIOUS SCRIPT
        set categories of aMessage to theList
    end repeat

    -- Workaround for Outlook 2016 Reminders window bug, part 2
    if windowClosed is true then
        tell application "System Events" to keystroke "9" using command down
    end if

end tell

J'espère que cela aidera quelqu'un d'autre qui cherche une solution pour ajouter une catégorie à des e-mails Outlook sélectionnés avec AppleScript.

Une grande amélioration serait de supprimer la première étape manuelle consistant à obtenir l'identifiant de la catégorie souhaitée, et de permettre à la place de définir la catégorie via le nom textuel de la catégorie, en parcourant en boucle toutes les catégories existantes dans Outlook jusqu'à ce que vous la trouviez, et puis en appliquant que id aux courriels sélectionnés. Je serais reconnaissant si quelqu'un améliorait ma version de cette façon et la partageait.