Recréer les anciens alias en masse pour réduire la taille de leur fichier, en conservant leur nom et leur date de création.

Voici une solution plutôt efficace utilisant AppleScript. Dans script Editor.app/Préférences, sélectionnez l'option pour "Afficher le menu script dans la barre de menu" & "Afficher les script de l'ordinateur".

Puis collez le code AppleScript suivant dans un nouveau document de l'éditeur script. Enregistrez ensuite ce nouveau document AppleScript sous forme de fichier .scpt à l'emplacement suivant...

/Utilisateurs/votre nom court/bibliothèque/scripts/

En gros, ce code AppleScript prendra les fichiers alias sélectionnés dans votre fenêtre Finder avant et créera de nouveaux fichiers alias à l'emplacement de votre choix. Si cet emplacement d'enregistrement est différent de l'emplacement de vos fichiers alias actuels, vous aurez la possibilité de supprimer vos fichiers alias originaux. Ce code conservera la date de création des fichiers originaux, mais la date de modification sera celle de la création des fichiers alias.

tell application "Finder" to set oldAliasFileList to selection as alias list

set theOriginalFiles to {}

repeat with oldAliasFile in oldAliasFileList
    try
        tell application "Finder" to set end of theOriginalFiles to ¬
            (original item of oldAliasFile) as alias
    on error errMsg number errNum
        display dialog "Some Item In Your Finder Selection Is Not An Alias File
 Or Its Original Item Cannot Be Found" buttons {"Cancel", "OK"} default button "OK"
        return
    end try
end repeat

activate
set theFolderChoice to display dialog ¬
    "Choose A Destination Folder For Your New Alias Files" buttons ¬
    {"Cancel", "OK"} default button "OK"

if button returned of theFolderChoice is "OK" then
    activate
    set aliasFileDestinationFolder to (choose folder)
else
    return
end if

repeat with thisFile in theOriginalFiles
    tell application "Finder"
        set {creationDate, modificationDate} to {creation date, modification date} of thisFile
        set aNewAliasFile to make new alias file ¬
            at aliasFileDestinationFolder to thisFile ¬
            with properties {creation date:creationDate, modification date:modificationDate}
    end tell
end repeat

activate
set deleteOldAliasFiles to display dialog ¬
    "Would You Like To Delete The Old Alias Files?" buttons ¬
    {"Cancel", "DELETE"} default button "DELETE"

if button returned of deleteOldAliasFiles is "DELETE" then
    tell application "Finder" to delete oldAliasFileList
end if