Comment définir la résolution de l'écran avec un raccourci clavier sur un MBP Retina ?

J'utilise un AppleScript qui bascule entre 3 des options 'scale' en fonction de l'option courante...

local index1, index2, index3

set index1 to 3 -- 1440 x 900 (Best for Retina)
set index2 to 4 -- 1680 x 1050
set index3 to 5 -- 1920 x 1200 (More Space)

-- Launch "System Preferences", open the "Displays" options and change to the "Display" tab
tell application "System Preferences"
    activate
    set the current pane to pane id "com.apple.preference.displays"
    reveal anchor "displaysDisplayTab" of pane id "com.apple.preference.displays"
end tell

local indexToUse

-- Now lets make the necessary changes
tell application "System Events"
    tell window "Color LCD" of application process "System Preferences" of application "System Events"
        tell tab group 1

            -- Click the "Scaled" radio button
            click radio button "Scaled"

            tell radio group 1 of group 1
                -- Depending on what scale option/index is current selected, set the appropriate new option/index to use
                if (value of radio button index1) is true then
                    set indexToUse to index2
                else if (value of radio button index2) is true then
                    set indexToUse to index3
                else
                    set indexToUse to index1
                end if

                -- Click the radio button for the new scale option/index
                click radio button indexToUse
            end tell

        end tell

        -- If option/index 1 is selected a warning prompt is displayed, click the OK button to dismiss the prompt
        if indexToUse = 1 then
            click button "OK" of sheet 1
        end if
    end tell
end tell

-- Quit "System Preferences"
quit application "System Preferences"

Je n'ai pas de MacBook Pro avec un écran Retina, donc vous devez probablement changer les numéros des lignes. Je ne sais pas si cela fonctionnerait avec plusieurs écrans.

tell application "System Preferences"
    reveal anchor "displaysDisplayTab" of pane "com.apple.preference.displays"
end tell
tell application "System Events" to tell process "System Preferences"
    tell tab group 1 of window 1
        click radio button "scaled"
        tell table 1 of scroll area 1
            if selected of row 1 then
                set selected of row 2 to true
            else
                set selected of row 1 to true
            end if
        end tell
    end tell
end tell
quit application "System Preferences"

Vous pouvez donner à la script un raccourci avec Alfred ou FastScripts ou en créant un service Automator .

D'accord, donc SwitchResX 4 semble être en mesure de le faire, en quelques étapes faciles.

1. Installez SwitchResX 4 (Duh).
2. Lancez le volet des préférences de SwitchResX 4, qui devrait ressembler à ce qui suit :
3. De là, allez à Display Sets et ajoutons un nouvel ensemble, que nous appellerons Retina - Full Size et le faire correspondre à une combinaison de touches de raccourci (dans ce cas, j'ai choisi opt + F1 ), et sélectionnez la résolution pleine grandeur (1920 x 1200).
4. Créez un deuxième ensemble, que nous appellerons Retina - Better Looking et l'affecter à la résolution et aux clés appropriées (j'ai choisi 1600 x 1000 &). opt + F2 respectivement).
5. ? ??
6. Profit ! Vous avez maintenant configuré SwitchResX pour qu'il soit capable de commuter la résolution. (Note : Ce programme est un shareware, et je n'y suis associé d'aucune manière. Je suis tombé dessus en faisant une simple recherche sur Google).

Quicksilver Vous pouvez également le faire si vous activez le plugin Displays. Je l'utilise tout le temps. Vous pouvez également affecter des déclencheurs à des résolutions/actions spécifiques.

Voir aussi http://mac.appstorm.net/roundups/utilities-roundups/10-essential-quicksilver-plugins/ pour une description rapide. Et voici la description de l'aide :

Affiche le plugin
Le module d'affichage permet à Quicksilver d'indexer les écrans actuellement connectés à votre Mac, afin de définir les paramètres du bureau. ainsi que leur résolution, leur profondeur de couleur et leur taux de rafraîchissement.

Voir aussi Macbook Pro Retina fonctionnant en résolution native