Pour autant que je sache, il n'existe aucun moyen d'associer les fichiers .webloc à une application spécifique. Votre meilleure chance serait probablement d'utiliser un AppleScript.
J'ai créé un petit script qui permet de générer de toutes petites applications AppleScript qui s'ouvrent dans le navigateur que vous sélectionnez lors de la création (OmniWeb, Safari ou Chrome).
Vous pouvez télécharger le script. aquí ou compilez-le vous-même à partir du code ci-dessous.
set theURL to text returned of (display dialog "What URL would you like to bookmark?" with title "Enter URL" default answer "http://")
set theApp to (choose from list {"OmniWeb", "Safari", "Chrome"} with prompt "Which application would you like to associate with the bookmark?" with title "Select Application") as string
set theName to text returned of (display dialog "What would you like to name the bookmark?" with title "Enter Name" default answer "")
set theFolder to choose folder with prompt "Where would you like to save the bookmark?"
if theApp is "OmniWeb" then
set theScript to "tell application \"OmniWeb\"
activate
try
set theTab to make new tab at end of front browser with properties {address:\"" & theURL & "\"}
set active tab of front browser to theTab
on error
make new browser with properties {address:\"" & theURL & "\"}
end try
end tell"
else if theApp is "Safari" then
set theScript to "tell application \"Safari\"
activate
try
set theTab to make new tab at end of tabs of front window
set the URL of theTab to \"" & theURL & "\"
on error
make new document
set theTab to tab 1 of front window
set the URL of theTab to \"" & theURL & "\"
end try
set current tab of front window to theTab
end tell"
else if theApp is "Chrome" then
set theScript to "tell application \"Google Chrome\"
activate
if (count of windows) = 0 then
make new window
set URL of tab 0 of front window to \"" & theURL & "\"
else
set URL of (make new tab at end of tabs of front window) to \"" & theURL & "\"
end if
end tell"
end if
tell application "AppleScript Editor"
set theDoc to make new document with data theScript
save theDoc as "application" in ((theFolder as string) & theName & ".app")
end tell
En l'exécutant, vous serez invité à saisir l'URL, le navigateur avec lequel vous souhaitez qu'il s'ouvre et l'emplacement où enregistrer le "signet".
Vous pouvez le placer dans vos applications ou dans le dossier scripts pour y accéder facilement et l'invoquer chaque fois que vous voulez enregistrer une URL.
