AppleScript dans OS X 10.10 pour redimensionner la fenêtre Safari et faire une capture d'écran de cette fenêtre, puis répéter l'opération avec plusieurs tailles.

Je n'ai eu qu'un partiel qui fonctionne à l'exception de quelques petits problèmes.

Tout d'abord, il n'est pas possible de stocker l'URL dans le nom du fichier (à cause des barres obliques et des caractères spéciaux) ; vous devez donc spécifier le nom du site Web.

Mais surtout, jusqu'à présent, l'importation CSV n'est pas implémentée. Le CSV est-il vraiment une exigence stricte, ou pourriez-vous obtenir la liste des URL dans un autre format ? Sinon, veuillez mettre à jour votre question avec des lignes exemplaires de votre fichier CSV. Je vais y travailler et mettre à jour ma réponse dès que possible.

on open_url(theUrl, theUrlName, x0, y0, xSize, ySize)
    tell application "Safari"
        open location theUrl
        activate

        set bounds of window 1 to {x0, y0, xSize, ySize}
        set windowID to id of window 1
        set the_state to missing value

        repeat until the_state is "complete"
            set the_state to (do JavaScript "document.readyState" in document 1)
            delay 0.3
        end repeat

        set theFolder to POSIX path of (path to desktop as string)
        set shellCommand to "/usr/sbin/screencapture -l " & windowID & " " & quoted form of (theFolder & "Screen Shot " & theUrlName & " " & xSize & "x" & ySize & ".png")
        do shell script shellCommand

    end tell
end open_url

set resolutionList to {{640, 480}, {1024, 768}}
set siteList to {{"http://www.apple.com", "Apple"}, {"http://www.google.com", "Google"}}

repeat with resolution in resolutionList
    set xSize to item 1 of resolution
    set ySize to item 2 of resolution
    repeat with theSite in siteList
        set theUrl to item 1 of theSite
        set theUrlName to item 2 of theSite
        open_url(theUrl, theUrlName, 0, 0, xSize, ySize)
    end repeat
end repeat

Il est préférable de vérifier que le chargement de la page est terminé avant de faire une capture d'écran. En prenant le code de réponse partiel original d'Asmus, quelque chose du genre...

delay 10

tell application "Safari"
    do JavaScript "document.readyState == 'complete'" in window 1's current tab
end tell
set loaded to result
if loaded is true then
    set shellCommand to "/usr/sbin/screencapture -l " & windowID & " " & quoted form of (theFolder & "Screen Shot " & theUrlName & " " & xSize & "x" & ySize & ".png")
    do shell script shellCommand
end if

...s'en chargera.