Il semble que kMDItemPath ne puisse pas faire ce dont vous avez besoin :

pas de résultats dans les recherches contre les kmditempath

Certaines alternatives potentielles sont discutées ici :

comment-localiser-un-fichier-dans-la-lumière-utilisant-le-dossier-et-le-nom-de-fichier

Il existe une solution de contournement, mais elle n'est pas très jolie. Cependant, elle répondra à vos besoins si vous souhaitez simplement accéder à vos README dans un seul dossier (en utilisant les critères que vous avez spécifiés), et avoir une idée de leur provenance.

L'idée est d'utiliser votre shell script pour trouver les bons fichiers, puis de rassembler les alias de chaque fichier dans un répertoire. Nous renommons ensuite les alias pour nous indiquer à quel répertoire parent appartient le fichier original.

L'Applescript pour faire cela est ci-dessous. Il semble laid ici, mais essayez de le coller dans l'éditeur script et de le compiler, et vous devriez être en mesure de voir la logique.

--- Set up the name of the folder to contain search results
set myFolder to POSIX file "/Users/me/SmartFolder"

--- Clear the folder of contents. Then we will see only the results of an updated search
tell application "Finder"
    display dialog "WARNING. This will delete all files below " & (POSIX path of myFolder) & " . Are you sure you want to continue?"
    delete (every item of folder myFolder)
    --- alternatively, if you want to keep your script in the same folder, replace the line above with
    --- delete ((every item of folder myFolder) whose name does not end with ".scpt")
end tell

--- The shell command that is doing all the searching
set FileList to do shell script "find /Users/me/Documents -type f -name README.md -not -path '*/node_modules/*'"

--- The rest of the script takes each file and makes an alias in our folder containing search results. The aliases are renamed according to "ParentDirectory_filename"
set FileList to paragraphs of FileList
repeat with CurrentFile in FileList
    set ASCurrentFile to POSIX file CurrentFile
    set PathList to words of (ASCurrentFile as string)
    --- Make the new name include the Parent Directory and file name
    set NewName to (item -2 of PathList) & "_" & (item -1 of PathList)
    tell application "Finder"
        make new alias file at myFolder to ASCurrentFile
        --- We need to save the name/location of the new alias file before we can try to rename it
        set NewAlias to result
        set i to 1
        repeat
            try
                --- Try to rename the alias. Won't work if there's already an alias with the new name
                set name of NewAlias to NewName
                exit repeat
            on error
                --- Append a number to the alias. Increase the number for more duplicates
                if i is not equal to 1 then
                    set NewName to text 1 thru -3 of NewName
                end if
                set NewName to NewName & " " & i
                set i to (i + 1)
            end try
        end repeat
    end tell
end repeat

Lorsque vous faites une requête brute, ajoutez simplement ceci :

(kMDItemPath != "folder to exclude")

David, dans la documentation de kMDItemPath :

"Chemin complet du fichier. La valeur de cet attribut peut être récupérée, mais ne peut pas être utilisée dans une requête ou pour trier les résultats de la recherche. Cet attribut ne peut pas être utilisé comme membre du paramètre de tableau valueListAttrs pour MDQueryCreate ou MDQueryCreateSubset."

J'ai essayé et ça ne marche pas

https://developer.apple.com/library/archive/documentation/CoreServices/Reference/MetadataAttributesRef/Reference/CommonAttrs.html#//apple_ref/doc/uid/TP40001694-SW1