Comment réparer les alias échoués?

Voici ma tentative de résoudre ce problème avec Applescript. Le script suivant prendra des alias sélectionnés dans le Finder et tentera de les relier au nouveau chemin en remplaçant Backup par External dans le chemin POSIX.

Je l'espère, c'est simple. Vous pourriez probablement le rendre récursif pour rechercher des alias dans des dossiers sélectionnés, mais c'est plus de travail que je ne suis prêt à faire - et puis il y a le problème de traiter les alias de dossiers. Les choses pourraient devenir compliquées. ;-)

J'espère que cela aide.

tell application "Finder"
    set these_items to the selection
end tell

repeat with i from 1 to the count of these_items
    set this_item to (item i of these_items) as alias
    set this_info to info for this_item

    if class of this_item is alias then
        tell application "Finder"
            set original_file to original item of this_item
            set this_alias_file_name to displayed name of this_item
            set container_folder to container of this_item

            set the_path to the POSIX path of (original_file as alias)
            set new_path to my replaceText("/Backup/", "/External/", the_path)

            move this_item to trash
            try
                make new alias file at container_folder to (POSIX file new_path) with properties {name:this_alias_file_name}
            on error errMsg number errorNumber
                if errorNumber is -10000 then -- nouveau fichier original non trouvé, essayer de relier à l'ancien
                    try
                        make new alias file at container_folder to (POSIX file the_path) with properties {name:this_alias_file_name}
                    on error errMsg number errorNumber
                        if errorNumber is -10000 then -- ancien original non trouvé. le lien est mort Jim
                            display dialog "Le fichier original de l'alias " & this_alias_file_name & " n'a pas été trouvé."
                        else
                            display dialog "Une erreur inconnue s'est produite:  " & errorNumber as text
                        end if
                    end try
                else
                    display dialog "Une erreur inconnue s'est produite:  " & errorNumber as text
                end if
            end try
        end tell
    end if
end repeat

on replaceText(find, replace, subject)
    set prevTIDs to text item delimiters of AppleScript
    set text item delimiters of AppleScript to find
    set subject to text items of subject

    set text item delimiters of AppleScript to replace
    set subject to "" & subject
    set text item delimiters of AppleScript to prevTIDs

    return subject
end replaceText