Comment créer un dossier dans le répertoire courant en vue liste ?

Voici un script que vous pouvez utiliser pour cela. Il fonctionne à la fois dans les vues en liste et en colonne. La partie renommage ne fonctionne pas correctement dans les vues icône et galerie, ce qui peut être gênant.

Pour l'utiliser avec un raccourci, je l'ai exporté en tant qu'application à partir de script Editor et j'ai défini un raccourci vers cette application dans Butler . J'ai utilisé le raccourci standard du Finder pour "Nouveau dossier", puisque je n'ai pas besoin des vues des icônes et de la galerie, mais vous pouvez préférer quelque chose de différent pour pouvoir quand même utiliser le raccourci normal. Notez que l'application doit obtenir des autorisations d'accessibilité (Préférences système ' Sécurité ' Confidentialité).

Vous pouvez ajuster les délais en fonction de la réactivité de votre système, car ils peuvent être gênants si vous avez l'habitude de taper le nom du nouveau dossier rapidement après sa création. Toutefois, s'ils sont trop faibles, le renommage ne fonctionnera pas.

-- By Philippe-André Lorin
-- 2020-12-13
-- macOS 10.14.4
-- See https://apple.stackexchange.com/a/408759/185198

-- Create folder inside currently selected folder
-- or at the same level as currently selected file

try
    tell application "Finder"
        set selectedItems to selection
        set currentPath to ((the first item of the selectedItems) as alias)

        -- Set parent path for future new folder
        if (currentPath as string) ends with ":" then
            -- It’s a folder
            set the parentPath to currentPath
        else
            -- It’s a file
            set {savedDelimiters, AppleScript's text item delimiters} to {AppleScript's text item delimiters, ":"}
            set the parentPath to (text items 1 thru -2 of (currentPath as string)) as string
            set AppleScript's text item delimiters to savedDelimiters
        end if

        -- Create new folder
        my createFolder(parentPath)
    end tell

on error -- No folder or file is selected
    tell application "Finder"
        set the currentPath to (folder of the front window as alias)
        my createFolder(currentPath)
    end tell
end try

on createFolder(folderLocation)
    tell application "Finder"
        -- Make new folder
        set thisFolder to make new folder at folderLocation
        delay 0.2 -- N.B. Without delays, the following operations sometimes fail.

        -- Select new folder
        set selection to thisFolder
        delay 0.2

        -- Call “Rename” menu in Finder
        activate
        tell application "System Events"
            tell application "System Events"
                tell process "Finder"
                    tell menu bar 1
                        -- N.B. The following must be adjusted to the Finder’s language settings
                        tell menu bar item "File"
                            tell menu "File"
                                click menu item "Rename"
                            end tell
                        end tell
                    end tell
                end tell
            end tell
        end tell

        -- Return
        return thisFolder
    end tell
end createFolder

Note. Ce script a été adapté du premier script de cette page : http://hints.macworld.com/article.php?story=20081119025327978