Obtenir une mauvaise URL à partir de l'onglet actuel de Safari avec Applescript

J'ai essayé de nombreuses fois de reproduire le problème, mais je n'y suis pas parvenu. J'ai donc testé cette solution en entrant manuellement deux fois une URL standard, par copier-coller, et en partant de là. J'ai également utilisé la mauvaise URL que vous avez indiquée dans votre question.

Dans Safari, il s'agit essentiellement d'essayer de construire une URL valide à partir de la double URL à l'aide d'un AppleScript exécuté en tant que service Automator lorsque vous appuyez sur la touche B et définit le document actuel (fenêtre, onglet) à l'URL appropriée.

Créez un service Automator avec les paramètres indiqués dans l'image ci-dessous et enregistrez-le sous :
Corriger une mauvaise URL

Puis, dans Préférences système > Clavier > Raccourcis > Services, faites défiler jusqu'à Général, sélectionnez
Fixer une mauvaise URL, cliquez sur Ajouter un raccourci et tapez : B

AppleScript code pour le service Automator :

on badURL()
    try
        --    # Put the bad URL on the Clipboard.
        tell application "Safari"
            activate
            delay 0.5
            tell application "System Events"
                key code 37 using {command down} # L
                delay 0.5
                key code 8 using {command down} # C
                delay 0.5
            end tell
        end tell
        --    # Retrieve the bad URL from the Clipboard.
        set theBadURL to get (the clipboard)
        --    # Trim the first eight characters off of 'theBadURL'.
        --    # This is done because the bad URL can have an occurrence of both 'http' and 'https' in the string in either
        --    # order and by trimming off, it lessens the amount of logic necessary to build a good URL from the bad URL.
        --    # The good URL, after all, is going to be built from what's after the second occurrence of either one. 
        --    # Test first for 'https' then 'http', as that makes more sense logically to do so.            
        set theBadURL to do shell script "awk 'BEGIN { print substr(\"" & theBadURL & "\", 9) }'"
        --    # Build the good URL from the bad URL.
        set theGoodURL to do shell script "awk -F 'https.*//' '{print $2}'<<<" & quoted form of theBadURL
        if theGoodURL is not equal to "" then
            set theGoodURL to "https://" & theGoodURL
        else
            set theGoodURL to do shell script "awk -F 'http.*//' '{print $2}'<<<" & quoted form of theBadURL
            if theGoodURL is not equal to "" then
                set theGoodURL to "http://" & theGoodURL
            end if
        end if
        return theGoodURL
    on error eStr number eNum
        display dialog eStr & " number " & eNum buttons {"OK"} default button 1 with icon caution
        return
    end try
end badURL

on run
    try
        tell application "Safari"
            activate
            set thisTabsURL to (get URL of current tab of window 1)
            --    # Check for bad URL and if found, build a good URL from it.
            tell current application
                if thisTabsURL contains "file:" then
                    set theGoodURL to my badURL()
                    tell application "Safari" to set the URL of the front document to theGoodURL
                end if
            end tell
        end tell
    on error eStr number eNum
        display dialog eStr & " number " & eNum buttons {"OK"} default button 1 with icon caution
        return
    end try
end run

Notez que, bien que j'aie testé cette méthode sous OS X 10.8.5 et MacOS 10.12 et qu'elle ait fonctionné dans mes conditions de test, il se peut qu'elle ne fonctionne pas correctement à chaque fois et dans toutes les conditions. try y on error déclarations sont utilisés dans le code . Nous espérons que cela permettra de détecter toute erreur et d'obtenir un résultat approprié afin d'améliorer l'efficacité du système. code pour gérer toute(s) erreur(s) qui ne se sont pas produites pendant mes tests.