Ouvrir une nouvelle fenêtre Safari dans l'espace actuel à partir du Terminal avec plusieurs onglets (URL)

Voici un AppleScript qui devrait vous aider. Ouvrez l'éditeur AppleScript et enregistrez ceci comme un script. J'ai modifié la source que j'ai trouvée aquí pour prendre en charge la prise en compte des arguments sur la ligne de commande.

Utilisez-le comme ça :

osascript new_window.scpt http://www.google.com http://www.stackoverflow.com

Bien sûr, remplacez les URLs ci-dessus par vos propres URLs.

nouvelle_fenêtre.scpt

on run argv
    tell application "Safari"
        if (count argv) = 0 then
            -- If you dont want to open a new window for an empty list, replace the
            -- following line with just "return"
            set {first_url, rest_urls} to {"", {}}
        else
            -- `item 1 of ...` gets the first item of a list, `rest of ...` gets
            -- everything after the first item of a list.  We treat the two
            -- differently because the first item must be placed in a new window, but
            -- everything else must be placed in a new tab.
            set {first_url, rest_urls} to {item 1 of argv, the rest of argv}
        end if

        make new document at end of documents with properties {URL:first_url}
        tell window 1
            repeat with the_url in rest_urls
                make new tab at end of tabs with properties {URL:the_url}
            end repeat
        end tell
        activate
    end tell
end run

Vous pourriez même créer un alias pour cela dans le Terminal et être en mesure de l'utiliser plus facilement. J'ajouterais ce qui suit à ~/.bash_profile :

alias newwindow='osascript /path/to/new_window.scpt'

Appelez newwindow tout ce que vous voulez. Sauvegarder .bash_profile et redémarrez le terminal pour qu'il fonctionne.

Au cas où quelqu'un chercherait une solution similaire pour Google Chrome, voici une version différente de la même idée.

chrome_new_window.scpt

on run argv
    tell application "Google Chrome"
        if (count argv) = 0 then
            make new window
        else
            tell (make new window)
                set URL of active tab to item 1 of argv
                repeat with the_url in the rest of argv
                    open location the_url
                end repeat
            end tell
        end if
        set active tab index of first window to 1
        activate
    end tell
end run