Apple script : Impossible d'obtenir la date de "2018-12-12 10:00 AM"

Les dates AppleScript sont notoirement pointilleuses en matière de format. Elles se basent sur les paramètres de date et d'heure de votre propre système, donc même si je parvenais à faire fonctionner correctement un script sur mon système en utilisant un format de date et d'heure spécifique, il ne fonctionnerait probablement pas sur votre système à moins que vous n'ayez les mêmes paramètres MacOS.

Par conséquent, la meilleure façon de traiter les objets date AppleScript est de les créer de toutes pièces en utilisant les composants jour, mois, année et heure. De cette façon, ils fonctionnent de manière cohérente sur tous les systèmes, mais, plus important encore, vous permettent de les manipuler dans votre propre script sans erreurs inattendues.

Ajoutez le gestionnaire suivant au bas de votre script. Il vous donnera les moyens de créer un objet date AppleScript en lui fournissant le jour, le mois et l'année, et (facultativement) les composantes heure, minute et seconde :

to makeASDate given year:y as integer ¬
    , month:m ¬
    , day:d as integer ¬
    , hours:h as integer : 0 ¬
    , minutes:min as integer : 0 ¬
    , seconds:s as integer : 0
    local y, m, d, h, min, s

    tell the (current date) to set ¬
        [ASDate, year, its month, day, time] to ¬
        [it, y, m, d, h * hours + min * minutes + s]

    ASDate
end makeASDate

Pour l'utiliser, il suffit d'appeler le gestionnaire comme suit :

makeASDate given year:2018, month:January, day:23
    --> date "Tuesday, 23 January 2018 at 00:00:00"

o

makeASDate given year:2018, month:1, day:23, hours:14, minutes:30, seconds:00
    --> date "Tuesday, 23 January 2018 at 14:30:00"

Maintenant, votre prochaine tâche est d'extraire les composants année, mois et jour de vos variables afin de les passer à la fonction makeASDate manipulateur. Le moyen le plus simple d'y parvenir est de diviser vos variables de date/heure en mots. Par exemple, avec votre date et heure de début :

set [sy, sm, sd] to words of (sDate of theResult)
    --> {"2018", "12", "12"}

set [sh, smin, AMPM] to words of (sTime of theResult)
    --> {"10", "00", "AM"}
if AMPM = "PM" then set sh to sh + 12

et de même avec votre fin des temps. J'ai illustré un test rapide avec votre variable d'heure pour déterminer s'il s'agit de AM ou de PM, et j'ai modifié la valeur de la composante horaire en conséquence (le paramètre makeASDate utilise l'horloge de 24 heures). Vous devrez effectuer un autre test avec votre variable de date pour déterminer le format de la date : dd/mm/yyyy o yyyy-mm-dd ce qui pourrait être aussi simple que :

if (sDate of theResult) contains "-" then
    set [sy, sm, sd] to words of (sDate of theResult)
else if (sDate of theResult) contains "/" then
    set [sd, sm, sy] to words of (sDate of theResult)
end if

Ce que @CJK a dit -- essayer de préparer une chaîne de date est une bataille perdue d'avance car cela dépend des paramètres de l'utilisateur, utilisez plutôt les composants -- sauf que leur gestionnaire ne fonctionne pas toujours. Si vous l'exécutez sur un jour dont le numéro est supérieur au nombre de jours du mois de l'entrée, le résultat sera le mois après celui que vous avez demandé. Par exemple, si vous demandez "month:2 day:15" le 31 janvier, vous obtiendrez le 15 mars et non le 15 février. Trois facteurs entrent en jeu, dont aucun ne semble être explicitement documenté :

1. AppleScript date les objets sont stockés comme un point absolu dans le temps, et non comme un ensemble de composants. (Enfin, surtout absolu : pour des raisons historiques, ils sont relatifs au fuseau horaire actuel). Les composants sont synthétisés à la demande à partir de ce point dans le temps en utilisant le calendrier actuel.

2. Le réglage d'un composant, tel que set month of d to April Cela signifie qu'il décompose la date en éléments, modifie l'un de ces éléments, puis les recompose en un point dans le temps. Ce qui se passe si l'un des composants est hors de la plage n'est pas spécifié, mais en pratique, un jour hors de la plage sera enveloppé dans un mois suivant. Considérons, en continuant l'exemple, set day of d to 41 . Le 41 avril est, logiquement, 11 jours après le dernier jour d'avril, le 30 avril, ce qui donne le 11 mai.

3. Même en utilisant la syntaxe du jeu de motifs set {x, y} to {1, 2} les affectations se font une par une. (La documentation https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_cmds.html#//apple_ref/doc/uid/TP40000983-CH216-SW52 les décrit comme "simultanées", puisque set {x, y} to {y, x} échange en effet x y y mais ce n'est pas tout à fait exact : ce qui se passe réellement, c'est qu'il évalue d'abord toutes les expressions, en stockant les résultats dans des temporaires implicites, puis affecte les temporaires aux variables une par une. Toutes les évaluations se produisent avant toutes les affectations, mais l'ordre n'est pas spécifié par ailleurs).

Supposons donc que vous exécutez ce programme le 31 janvier 2020 :

makeASDate given year:2018, month:2, day:15

Ce qui se passe, c'est que :

1. set ASDate to (current date) . ASDate correspond au 31 janvier 2020, quelle que soit l'heure actuelle.
2. set year of ASDate to 2018 . L'ASDate est maintenant le 31 janvier 2018.
3. set month of ASDate to 2 . Les composants précisent le 31 février 2018, qui n'existe pas, donc cela s'enroule : d est maintenant le 3 mars 2018.
4. set day of ASDate to 15 . d est maintenant le 15 mars 2018, et non le 15 février comme vous l'aviez demandé.

Il y a deux façons de contourner ce problème : la première consiste à définir d'abord l'option day y month dans cet ordre à 1 d'abord, puis appliquer les paramètres d'entrée. L'autre solution consiste à utiliser une date fixe avec un mois et un jour à faible numérotation, par exemple "1/1/1904", au lieu de current date comme point de départ. Un gestionnaire corrigé pourrait ressembler à ceci :

to makeASDate given year:y as integer ¬
    , month:m ¬
    , day:d as integer ¬
    , hours:h as integer : 0 ¬
    , minutes:min as integer : 0 ¬
    , seconds:s as integer : 0
    local y, m, d, h, min, s, p

    set p to "1/1/1904"
    tell the (date p) to set ¬
        {ASDate, year, its month, day, time} to ¬
        {it, y, m, d, h * hours + min * minutes + s}

    ASDate
end makeASDate