AppleScript pour connecter la Magic Mouse sur iMac

Il semble que vous savez comment créer un Service ou une Quick Action système, et avez juste besoin d'un script pour ouvrir la connexion bluetooth réelle. Testez le script ci-dessous initialement dans Script Editor, ce qui nécessite que tout appareil auquel vous souhaitez vous connecter ait déjà été apparié (il semble que ce soit le cas). Si tout se passe bien, vous pouvez être raisonnablement confiant que cela fonctionnera si vous le transplantez dans un flux de travail Automator (après vous être débarrassé de tout code exemple qui apparaît, c'est-à-dire on run {input, parameters} etc.)

use framework "Foundation"
use framework "IOBluetooth"

property this : a reference to the current application
property nil : a reference to missing value
property _1 : a reference to reference

property IOBluetoothDevice : a reference to IOBluetoothDevice of this
property NSPredicate : a reference to NSPredicate of this

property pairedDevices : a reference to IOBluetoothDevice's pairedDevices
property text item delimiters : linefeed & tab & "- "

to deviceWithName(name as text)
    local name
    NSPredicate's predicateWithFormat:"name==[c]%@" argumentArray:[name]
    tell filteredArrayUsingPredicate_(result) of pairedDevices
        if |count|() > 0 then return its firstObject()
        error {"Aucun appareil portant ce nom. Appareils disponibles :", ¬
            getDeviceNames() of me} as text
    end tell
end deviceWithName

to getDeviceNames()
    (pairedDevices's valueForKey:"name") as list
end getDeviceNames

try
    if deviceWithName("Magic Mouse 2")'s openConnection() != 0 ¬
        then error "Impossible d'ouvrir la connexion."
on error E
    return E
end try

true

NB. Ce script a seulement été testé dans High Sierra

Je crains que les messages d'erreur ne soient pas particulièrement informatifs si quelque chose ne fonctionne pas comme prévu. Mais, si l'appareil peut se connecter, le script devrait pouvoir le gérer. S'il échoue à se connecter, testez si vous êtes capable d'établir une connexion manuellement.