Événement basé sur le niveau de charge de la batterie

Bon, cette question est ancienne mais j'ai rencontré une situation similaire et j'ai voulu lancer un raccourci (avec "Siri Shortcuts") sur MacOS 12 sur certains niveaux de batterie.

Au lieu d'un service d'arrière-plan, j'ai décidé qu'un script fonctionnerait mieux pour moi puisqu'il devrait allumer et éteindre ma prise HomeKit à laquelle le chargeur est connecté. (Mais seulement pendant que le MacBook est en train de transcoder un film).

A partir de la réponse de Joseph, j'ai pris les morceaux qui fonctionnent encore et j'ai créé un Tcl script qui vérifie le niveau de la batterie toutes les minutes.

J'ai créé un fichier nommé batt.tcl avec le contenu suivant :

#!/usr/bin/env tclsh

set run 1
set last 0
set logs 1
set logfile "batt.log.txt"
set settingsfile batt.cfg
set min 15
set max 80
set delay 10000

# leave "nil"; we need a wake lock when we're charging. This is done using a call "caffeinate",     waiting for another PID to be removed.
set wakeLock "nil"

proc log {message} {
  if {$::logs != 1} {
    return
  }
  set msg ""
  append msg [clock format [clock seconds] -format "%d.%m.%Y %H:%M:%S"]
  append msg ": "
  append msg $message
  set of1 [open $::logfile a]
  puts $of1 $msg
  close $of1
}

proc enableWakeLock {} {
  if {$::wakeLock == "nil"} {
    log "Enabling wake lock"
        set ::wakeLock [open "|tclsh" r+]
    set myProcess [pid $::wakeLock]
    exec caffeinate -i -w $myProcess &
  }
}

proc disableWakeLock {} {
  if {$::wakeLock != "nil"} {
    log "Disabling wake lock"
    puts $::wakeLock "exit\n"
    flush $::wakeLock
    close $::wakeLock
    set ::wakeLock "nil"
  }
}

proc replaceAll {input lookup replacement} {
  set offs 0
  set mapping [list $lookup $replacement]
  while {$offs != -1} {
    set input [string map $mapping $input]
    set offs [string first $lookup $input]
  }
  return $input
}

proc loadSettings {} {
  if {[file exists $::settingsfile]} {
    set if1 [open $::settingsfile]
    set data [read $if1]
    close $if1

    set data [string map [list \t " " \n " " \r " "] $data]
    set data [replaceAll $data "  " " "]
    set data [string trim $data " "]

    set lines [split $data " "]
    set id ""
    foreach line $lines {
      if {[string index $line 0] != "#"} {
        if {[string length $id] == 0} {
          set id $line
        } else {
          switch -exact -- $id {
            "low:" {
              set ::min $line
              set id ""
            }
            "high:" {
              set ::max $line
              set id ""
            }
            "logs:" {
              set ::logs $line
              set id ""
            }
            "logfile:" {
              set ::logfile $line
              set id ""
            }
            default {
              puts "Unknown config option <$id>. Aborting."
              exit
            }
          }
        }
      }
    }
  } else {
    puts -nonewline "Generating settings file"
    flush stdout
    set of1 [open $::settingsfile w]
    puts $of1 [list "low:" $::min]
    puts $of1 [list "high:" $::max]
    puts $of1 [list "logfile:" $::logfile]
    puts -nonewline $of1 [list "logs:" $::logs]
    flush $of1
    close $of1
    puts ", done."
  }

  if {$::logs != 1 && $::logs != 0} {
    set msg "Weird \"logs:\" setting: must be 1 or 0. Aborting."
    puts $msg
    exit
  }

  if {$::min >= $::max} {
    set msg "Weird configuration: low charge ($::min) is equal or higher that high charge ($::max). Aborting."
    puts $msg
    exit
  }

}

proc waypointSearch {input waypoints endwaypoint} {
  set offs 0
  set len 0
  foreach wp $waypoints {
    set len [string length $wp]
    set offs [string first $wp $input $offs]
    if {$offs < 0} {
      puts "Waypoint \"$wp\" not found."
    }
#    puts "WP: <$wp> $offs $len"
  }
  set eoffs [string first $endwaypoint $input $offs]
  if {$eoffs < 0} {
    puts "Waypoint \"$endwaypoint\" not found."
  }
  return [string range $input [expr $offs + $len] [expr $eoffs - 1]]
}

loadSettings

set msg "Starting with settngs for low: $min and high: $max."
puts -nonewline "\n\nlow: $min, high: $max"
log $msg

while {$run == 1} {

  set input [exec ioreg -l]
  set lvl [waypointSearch $input [list "AppleSmartBattery " "\"CurrentCapacity\"" "="] "\n"]
  set level [string trim $lvl " \t\n"]

  set changes 0

  if {$last != $level} {
    set v [expr abs(abs($last - $level)-1) * -10000]
    set wouldBe [expr $delay + $v]
    if {$v < 0 && $wouldBe > 0} {
      set delay $wouldBe
      set changes 1
    }

    if {$level <= $::min} {
      set last $level
      set msg "Batt low: $level"
      puts -nonewline "\n" 
      puts -nonewline $msg
      log $msg
      enableWakeLock
      exec shortcuts run mac-battery-low
      continue
    } elseif {$level >= $::max} {
      set last $level
      set msg "Batt high: $level"
      puts -nonewline "\n" 
      puts -nonewline $msg
      log $msg
      exec shortcuts run mac-battery-high
      disableWakeLock
      continue
    }
  } else {
    set canMaxBe [expr ($level*3000)]
    if {$delay + 10000 <= $canMaxBe} {
      incr delay 10000
      set changes 1
    }
  }

  if {$last != $level} {
    set changes 1
  }

  set last $level
  if {$changes == 1} {
    puts -nonewline "\n" 
    puts -nonewline "Batt: $level"
    puts -nonewline " ([expr $delay/1000] s)"
    flush stdout
  }
  after $delay

}

Puis j'ai créé 2 raccourcis pour "Siri Shortcuts" et les ai nommés mac-battery-low et mac-battery-high . Le premier allume la prise, le second l'éteint.

Sur le Terminal, je lance simplement tclsh batt.tcl (ou chmod 755 batt.tcl et double-cliquez sur le fichier) pour commencer à surveiller la batterie. Ctrl + C mettra fin à la surveillance.

Modifier

Supprimé.

(Cela portait à confusion puisque le script a été mis à jour et présente une meilleure solution).

Edit2

Ce que j'ai trouvé jusqu'à présent :

1. Le processus de "caféination" maintient le système en état de marche.
2. Nous devrions seulement caféiner le système pendant la charge, car il y a aussi d'autres processus qui caféinent pendant que l'utilisateur est actif.

-> Il n'y a donc pas besoin de vérifier pmset -g assertions pour les assertions existantes.

3. Nous devons simplement créer une assertion propre qui maintient le Mac allumé pendant la charge. Lorsque nous avons atteint le niveau de batterie souhaité, nous déclenchons notre événement pour supprimer l'assertion. Tout processus de caféination peut être encore en cours d'exécution et maintenir le système allumé. Ou bien il est déjà terminé - ce qui permet au Mac de se mettre en veille immédiatement.

Nous permettons donc au système de se mettre en sommeil profond à tout moment si le chargeur est éteint. Cependant, d'autres personnes pourraient empêcher le sommeil profond et ainsi nous permettre de continuer à fonctionner. (vérification périodique)

J'ai mis à jour le script ci-dessus. . Lors de la première exécution, il crée un fichier de paramètres qui vous permet de modifier les valeurs pour les sessions ultérieures sans définir de paramètres.