Désactiver la notification Growl lorsqu'une certaine application est en cours d'exécution

Tout le mérite revient à @ghoppe sur Super User pour cette excellente réponse . Je ne fais que le dupliquer ici parce qu'un modérateur sur Méta a suggéré qu'il serait approprié de le faire.

Veuillez noter que cette solution supprimera Growl lorsque VLC (lecteur multimédia) est en cours d'exécution. Pour que cela fonctionne pour une autre application (par exemple QuickTime), vous devrez modifier l'Applescript. Si vous avez essayé par vous-même mais que vous avez encore besoin d'aide, je vous suggère de poster une question à ce sujet à la rubrique Stack Overflow .

La réponse originale suit :

Entrez dans l'éditeur Applescript, enregistrez sous forme d'application et, lors de l'enregistrement, cochez la case "Stay Open". Utilisez cette nouvelle application Applescript pour lancer l'application VLC.

Description : Il lancera VLC, désactivera les notifications growl, vérifiera toutes les 2s si VLC a quitté, si oui il réactivera les notifications growl et quittera. En bonus, il utilisera les notifications de grognement pour vous avertir quand les notifications de grognement seront activées ou désactivées.

global Growl_was_Loaded    
global VLC_is_Loaded    

on run    
    set Growl_was_Loaded to isAppLoaded("GrowlHelperApp")    
    set VLC_is_Loaded to isAppLoaded("VLC")    
    launchVLC()    
    idle    
end run    

on idle    
    set x to isAppLoaded("VLC")    
    if x and not VLC_is_Loaded then    
        launchVLC()    
    else if VLC_is_Loaded and not x then    
        set VLC_is_Loaded to false    
        if Growl_was_Loaded then    
            tell application "GrowlHelperApp" to launch    
            growl_notify("Growl notifications have been turned ON")    
        end if    
        tell me to quit    
    end if    
    return 2 -- wait 2 seconds    
end idle    

on launchVLC()    
    tell application "VLC" to launch    
    if Growl_was_Loaded then    
        growl_notify("Launching VLC… Growl notifications have been turned OFF")    
        delay 1    
        tell application "GrowlHelperApp" to quit    
    end if    
    set VLC_is_Loaded to true    
end launchVLC    

on isAppLoaded(app_name)    
    tell application "System Events"    
        set app_list to every application process whose name is app_name    
        if the (count of app_list) > 0 then    
            set x to true    
        else    
            set x to false    
        end if    
    end tell    
    return x    
end isAppLoaded    

on growl_notify(msg)    
    tell application "GrowlHelperApp"    
        set the allNotificationsList to {"Growl Toggler"}    
        register as application "Growl Toggler" all notifications allNotificationsList default notifications allNotificationsList    
        notify with name "Growl Toggler" title msg description "" application name "Growl Toggler" icon of application "Automator"    
    end tell    
end growl_notify