Une option consisterait à examiner le latexmk et le caoutchouc avec leurs options de nettoyage.
Mais comme le nettoyage des fichiers .aux et des fichiers connexes n'est recommandé qu'après l'exécution de la compilation finale, ce qui suit semble présenter une solution très pratique pour les utilisateurs de MacOS. Une façon de nettoyer après coup lorsque vous utilisez TeXShop avec ses paramètres par défaut est d'ajouter cet AppleScript flexible au programme :
[citation] Une solution TeXShop
Comme d'autres l'ont mentionné, la suppression systématique des fichiers auxiliaires n'est généralement pas une bonne idée, surtout pour les documents complexes. Toutefois, il est utile de pouvoir les supprimer manuellement en cas de besoin.
J'utilise l'Applescript suivant (écrit par Claus Gerhardt) enregistré comme une macro dans TeXShop. Le script pourrait également être adapté à d'autres éditeurs Mac. Ce que j'aime dans ce script, c'est que je peux ajouter de nouvelles extensions de fichiers aux lorsque cela est nécessaire, et qu'il est capable de traiter les extensions aux à parties multiples comme -blx.bib, etc.
--AppleScript
-- Apply only to an already saved file
-- Claus Gerhardt, September 2006
(*This script gets the path of the frontmost (tex) document in TeXShop and removes the corresponding auxilary files the suffixes of which are listed in the list L. Beware of the quotation marks. The list L may contain suffixes to which no corresponding files exist.*)
my remove_auxiliaries()
on remove_auxiliaries()
set L to {".aux", ".synctex.gz", ".fdb_latexmk", ".out", ".toc", ".bbl", ".blg", ".ind", ".sind", ".run.xml","-blx.bib",".log", ".end", ".1"} as list
tell application "TeXShop"
get path of document of window 1
set fileName to result
end tell
set {baseName, texName, pdfName, namePath, dirName, dirNameunquoted, logName, logPath, rtfName, docName} to my setnamebbedit_rootn(fileName)
(*
tell application "TeXShop"
close document docName
end tell
*)
repeat with x in L
try
set shellScript to "cd " & dirName & ";"
set shellScript to shellScript & "rm -f " & baseName & x
do shell script shellScript
end try
end repeat
end remove_auxiliaries
on setnamebbedit_rootn(x)
set n to (number of characters of contents of x)
set fileNamequoted to quoted form of x
set windowName to do shell script "basename " & fileNamequoted
set m to (number of characters of contents of windowName)
set dirName to quoted form of (characters 1 thru (n - m - 1) of x as string)
set dirNameunquoted to (characters 1 thru (n - m - 1) of x as string)
set theText to contents of windowName as string
set n to (number of characters of contents of theText)
set i to n as number
repeat while i > 0
if character i of theText is equal to "." then
set m to i
exit repeat
else
set i to (i - 1)
end if
end repeat
set baseName to (characters 1 thru (m - 1) of theText as string)
set texName to baseName & ".tex"
set namePath to dirNameunquoted & "/" & baseName as string
set pdfName to namePath & ".pdf" as string
set rtfName to namePath & ".rtf" as string
set logPath to namePath & ".log" as string
set logName to baseName & ".log" as string
set theFile to POSIX file x as string
tell application "Finder"
get displayed name of the file theFile
end tell
set docName to result
return {baseName, texName, pdfName, namePath, dirName, dirNameunquoted, logName, logPath, rtfName, docName} as list
end setnamebbedit_rootn
[/endquote]
copié à partir d'ici (regardez aussi les autres suggestions)
