Dans iTunes 12 sous MacOS, comment puis-je réinitialiser le nombre de sauts d'une chanson ?

Le code AppleScript suivant fonctionne pour moi avec la dernière version de MacOS Mojave.

tell application "iTunes"
    tell its track "Insert Your Song Title"
        set its skipped count to 0 -- Enter Your Desired Number     
    end tell
end tell

Le code suivant résout le problème des chansons multiples portant le même nom.

tell application "iTunes"
    set theTrack to "Insert Your Song Title"
    set tracksRef to a reference to (tracks whose name is theTrack)

    set trackCount to count of tracksRef

    if trackCount is greater than 1 then
        set theArtists to artist of tracksRef
        set chooseArtist to (choose from list theArtists with title "Choose The Artist" with prompt ¬
            "Choose The Artist" OK button name "OK" cancel button name "Cancel") as text
        tell (every track whose name is theTrack and artist is chooseArtist)
            set skipped count to 0 -- Enter Your Desired Number     
        end tell
    else
        tell its track theTrack
            set its skipped count to 0 -- Enter Your Desired Number     
        end tell
    end if
end tell

Le code suivant devrait fonctionner si vous voulez remettre à zéro le nombre de sauts de chaque piste.

tell application "iTunes"
    set allTracks to every track
    repeat with i from 1 to count of allTracks
        set thisItem to item i of allTracks
        tell thisItem
            try
                set its skipped count to 0 -- Enter Your Desired Number     
            end try
        end tell
    end repeat
end tell

J'ai remarqué dans le commentaire de votre OP où vous avez répondu "Selected tracks" à la question du commentaire de dwightk "All tracks ? Ou les pistes sélectionnées ?" Donc...

Pour réinitialiser le compte des sauts de toutes les pistes sélectionnées, il suffit d'utiliser :

tell application "iTunes" to set skipped count of selection to 0