Supprimer un fichier actuellement ouvert directement dans l'application ?

Essayez ceci AppleScript dans un service Automator (vous pouvez attribuer une touche de raccourci à n'importe quel service) :

on run
    set x to path to frontmost application as string
    tell application x to if exists document 1 then
        try
            try
                set p to path of front document -- some app use --> path of document
                p
            on error
                set p to file of front document -- some app use -->  file of document
            end try
            my moveToTrash(p)
            close front document
        on error
            my speakText("can't delete this document")
        end try
    else
        my speakText("You have no open document in that application")
    end if
end run

on moveToTrash(p)
    if p starts with "/" then -- some app return posix path
        set tFile to p as POSIX file as alias
    else -- some app return HFS path
        set tFile to p as alias
    end if
    tell application "Finder" to delete tFile
end moveToTrash

on speakText(t)
    say t
end speakText

J'ai testé le script sur ces applications ( "BBEdit", "TextWrangler", "TextEdit", "Preview", "QuickTime Player", "Pages", "Numbers", "Keynote", "Automator", "AppleScript Editor", "Xcode", etc. ) sur Mavericks

Ce script ne fonctionnera pas avec certaines applications non-apple.

Pour affecter une combinaison de touches au service nouvellement créé :

Ouvrez l'application Préférences système et accédez au volet de préférences Clavier, puis sélectionnez l'onglet Raccourcis. Dans la liste située à gauche du volet de préférences, sélectionnez la catégorie Services. Une liste des services installés s'affiche sur la droite. Faites défiler jusqu'à la dernière catégorie intitulée Général, et localisez le service que vous venez de créer. Double-cliquez à l'extrême droite du nom du service pour activer le champ de saisie des touches, puis tapez la combinaison de touches que vous souhaitez affecter au service. Fermez l'application Préférences système.