Est-il possible de faire en sorte que le compteur de la boîte de réception d'OS X Mail affiche tous les messages (et pas seulement les messages non lus) ?

DockStar a résolu le problème pour moi. Il y a maintenant une mise à jour pour prendre en charge Mavericks et Yosemite lorsqu'ils sortiront. Je ne l'ai testé que sur Mavericks, mais il fonctionne parfaitement.

Ce qui est génial pour moi, c'est que j'ai exactement 4 boîtes de réception, donc je peux ajouter un badge pour chacune d'elles.

J'ai réussi à trouver une solution de contournement : J'ai un AppleScript qui s'exécute toutes les 10 minutes sur ma machine pour mettre TOUS les emails de ma boîte de réception au statut : non lu. Cela met à jour l'icône du badge dans le Dock. Comme je suis la philosophie de la boîte de réception zéro, je ne me soucie pas de savoir si les courriels que j'ai lus sont marqués comme non lus.

tell application "Mail" set read status of every message of inbox to false end tell

Je l'exécute toutes les 10 minutes sur Mac en utilisant cet excellent outil de planification de lanchd : LaunchControl de Soma Zone software.

Je vous recommande d'essayer d'abord ce script.

Vous pouvez modifier le rapport de sortie à votre guise (mais pas l'envoyer par courriel à vous-même).

Si vous êtes comme moi et que vous avez plusieurs comptes avec des centaines de dossiers et des milliers d'emails, le nombre de badges peut être déroutant.

Je viens de l'exécuter sur mon MBA et cela a pris un certain temps mais il a produit un rapport de 3 pages de TOUS les emails de tous les comptes dans tous les dossiers, tout en faisant la différence entre lu et non lu.

tell application "Mail"
set localMailboxes to every mailbox
if (count of localMailboxes) is greater than 0 then
set messageCountDisplay to "Local mailboxes (On My Mac)" & return & my getMessageCountsForMailboxes(localMailboxes)
else
set messageCountDisplay to ""
end if

set everyAccount to every account
repeat with eachAccount in everyAccount
set accountMailboxes to every mailbox of eachAccount
if (count of accountMailboxes) is greater than 0 then
set messageCountDisplay to messageCountDisplay & return & "Mailboxes for Account: " & name of eachAccount & return & my getMessageCountsForMailboxes(accountMailboxes)
end if
end repeat

set outputMessage to make new outgoing message with properties {content:messageCountDisplay, subject:"Message counts for all my mailboxes", visible:true}
tell outputMessage
set font to "Courier"
set size to 12
end tell
end tell

on getMessageCountsForMailboxes(theMailboxes)
-- (list of mailboxes)
-- returns string

set displayString to ""

tell application "Mail"
repeat with eachMailbox in theMailboxes
set mailboxName to name of eachMailbox
set messageCount to (count of (messages of eachMailbox)) as string
set unreadCount to unread count of eachMailbox as string

set displayString to displayString & " " & my padString(mailboxName, 40) & " " & messageCount & " (" & unreadCount & " unread)" & return
end repeat
end tell

return displayString
end getMessageCountsForMailboxes

on padString(theString, fieldLength)
-- (string, integer)
-- returns string

set stringLength to length of theString

if stringLength is greater than fieldLength then
set paddedString to (text from character 1 to character (fieldLength - 3) of theString) & "..."
else -- stringLength is less than or equal to fieldLength
set paddedString to theString

set paddingLength to fieldLength - stringLength
repeat paddingLength times
set paddedString to paddedString & space
end repeat
end if

return paddedString
end padString

Source :

Voici un extrait de ce à quoi il ressemble (moi bloquant mes informations personnelles)

Dans les préférences système, allez dans Notifications. Cliquez sur l'application Mail, puis cochez la case à droite qui dit "icône de l'application badge". C'est tout. Ça a marché pour moi.