Basculer le contrôle vocal avec un raccourci clavier ?

En exemple AppleScript code montré ci-dessous, a été testé dans scriptÉditeur sous MacOS Big Sur avec Langue et région paramètres dans Préférences du système réglé sur Anglais (US) - Primaire et a fonctionné pour moi sans problème 1 .

• 1 _{Assume les paramètres nécessaires et appropriés dans <strong>Préférences du système </strong>> <strong>Sécurité et confidentialité </strong>> <strong>Vie privée </strong>ont été fixés/réglés selon les besoins.}
• On suppose que la cible case à cocher a déjà été activé manuellement pour gérer la boîte de dialogue d'autorisation qui apparaît la première fois que la cible case à cocher a été basculé manuellement.

En exemple AppleScript code peut être utilisé dans un Exécuter AppleScript action dans un Automator Service/action rapide qui s'est vu attribuer un raccourci clavier sur Préférences du système > Clavier > Raccourcis > Services Cependant, d'après mon expérience, il est préférable d'utiliser l'un des éléments suivants applications tierces qui sont capables de fonctionner AppleScript code et en attribuant un raccourci clavier global .

• À titre d'exemple, j'utilise FastScripts pour certaines tâches, ainsi que Cuillère à marteau pour d'autres tâches. (Je ne suis pas associé aux développeurs de ces produits, juste un utilisateur satisfait).

Exemple AppleScript code :

--  # Check to see if System Preferences is 
--  # running and if yes, then close it.
--  # 
--  # This is done so the script will not fail 
--  # if it is running and a modal sheet is 
--  # showing, hence the use of 'killall' 
--  # as 'quit' fails when done so, if it is.
--  #
--  # This is also done to allow default behaviors
--  # to be predictable from a clean occurrence.

if running of application "System Preferences" then
    try
        tell application "System Preferences" to quit
    on error
        do shell script "killall 'System Preferences'"
    end try
    delay 0.1
end if

--  # Make sure System Preferences is not running before
--  # opening it again. Otherwise there can be an issue
--  # when trying to reopen it while it's actually closing.

repeat while running of application "System Preferences" is true
    delay 0.1
end repeat

--  # Open System Preferences to the Accessibility pane. 

tell application "System Preferences" to ¬
    reveal pane id "com.apple.preference.universalaccess"

tell application "System Events"
    tell application process "System Preferences"
        tell window 1

            --  # Wait for the target UI element to be available.

            set i to 0
            repeat until exists scroll area 1
                delay 0.1
                set i to i + 1
                if i  30 then return
            end repeat

            --  # Select Voice Control.

            try
                select (rows of table 1 of scroll area 1 ¬
                    whose value of static text 1 of ¬
                    UI element 1 is "Voice Control")
            end try

            --  # Wait for the target UI element to be available.

            set i to 0
            repeat until exists checkbox 3 of group 1
                delay 0.1
                set i to i + 1
                if i  30 then return
            end repeat

            --  # Click checkbox Enable Voice Control.

            click checkbox 3 of group 1

        end tell
    end tell
end tell

delay 0.2

tell application "System Preferences" to quit

Notas:

En exemple AppleScript code utilise Scripting de l'interface utilisateur qui peut être parfois maladroit, et en supposant que Préférences du système est normalement déjà fermé, le script entraînera le Préférences du système pour rebondir une fois sur l'icône Quai .

_{Remarque : Le <em>exemple </em><strong>AppleScript </strong><em>code </em>est juste cela et sans aucune inclusion <em>gestion des erreurs </em>ne contient pas d'autres <em>gestion des erreurs </em>comme il se doit. C'est à l'utilisateur qu'il incombe d'ajouter toute <em>traitement des erreurs </em>selon ce qui est approprié, nécessaire ou souhaité. Consultez le <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_control_statements.html#//apple_ref/doc/uid/TP40000983-CH6g-129232" rel="nofollow noreferrer"><strong>essayez </strong></a><em>déclaration </em>y <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_control_statements.html#//apple_ref/doc/uid/TP40000983-CH6g-129657" rel="nofollow noreferrer"><strong>erreur </strong></a><em>déclaration </em>dans le <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/introduction/ASLR_intro.html" rel="nofollow noreferrer"><strong>Guide du langage AppleScript </strong></a>. Voir aussi, <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_error_xmpls.html#//apple_ref/doc/uid/TP40000983-CH221-SW1" rel="nofollow noreferrer"><strong>Travailler avec des erreurs </strong></a>. En outre, l'utilisation de la <a href="https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/reference/ASLR_cmds.html#//apple_ref/doc/uid/TP40000983-CH216-SW10" rel="nofollow noreferrer"><strong>retarder </strong></a><em>commande </em>peut être nécessaire entre les événements, le cas échéant, par ex. <code>delay 0.5</code> avec le <em>valeur </em>de la <em>retarder </em>définis de manière appropriée.}