Comment faire en sorte qu'un lien s'ouvre dans une fenêtre Safari spécifique sous MacOS ?

Cela peut être fait avec une application AppleScript qui ouvre le lien dans Safari et fait de cette application le navigateur par défaut.

J'ai trouvé deux versions en testant : soit ouvrir dans de nouvelles fenêtres, soit dans de nouveaux onglets s'il y a déjà une fenêtre dans l'espace actuel.

• Ouvrez script Editor.app (ou encore mieux script Debugger)

• Si vous voulez que les liens s'ouvrent dans une nouvelle fenêtre utiliser ce

  on open location theURL    
      tell application "Safari"  
          make new document with properties {URL:theURL}  
          activate  
      end tell  
  end open location  

• Si vous voulez que les liens s'ouvrent dans une nouvel onglet (si une fenêtre est disponible dans l'espace actuel) utilisez ceci :

  on open location theURL  
      tell application "System Events"  
          tell process "Safari"  
              try  
                  set frontWinName to name of window 1 
              on error  
                  my openNewWindow(theURL)  
                  return  
              end try  
          end tell  
      end tell  
  
      tell application "Safari"  
          try  
              tell (first window whose name is frontWinName and miniaturized is false)  
                  set current tab to make new tab with properties {URL:theURL}  
                  activate  
              end tell  
          on error  
              my openNewWindow(theURL)  
          end try  
      end tell  
  end open location  
  
  on openNewWindow(theURL)  
      tell application "Safari"  
          make new document with properties {URL:theURL}  
          activate  
      end tell  
  end openNewWindow  

• Enregistrer comme application

• Si vous ne voulez pas que l'application soit affichée dans le dock

  • Faites un clic droit sur l'application, allez dans le paquet et trouvez Info.plist

  • Ajouter ceci dans Info.plist

    <key>LSUIElement</key>  
    <true/>

• Définir l'application comme navigateur par défaut (J'ai utilisé RCDefaultApp).

Si vous voulez voir à quel point le comportement des liens par défaut de MacOS est ennuyeux, je vous suggère de revenir à Safari comme navigateur par défaut après quelques heures ...

Je suis toujours sous 10.14.6 et je ne connais pas les restrictions possibles dans Catalina.

En tant que développeur, j'ai étudié la possibilité d'extensions permettant d'obtenir ce que l'on veut en ouvrant toujours un fichier nouveau lorsque vous cliquez sur un lien contenu en dehors de Safari lui-même. Je suis désolé de vous dire que je ne pense pas que cette approche soit possible.

Malheureusement, Safari n'offre pas aux extensions un moyen de déterminer l'identité de l'utilisateur. origine d'un nouvel onglet/fenêtre. Je veux dire par là qu'un nouvel onglet peut être créé parce que l'utilisateur clique sur un lien dans un e-mail, clique sur un lien dans Safari avec la touche Commande, ouvre un signet Safari en maintenant la touche Commande enfoncée, clique sur un lien dans un document PDF, ou toute autre action qui ouvre une page dans un nouvel onglet. Quelle que soit la méthode employée, Safari ne fournit pas d'informations sur l'ouverture d'un nouvel onglet. comment la fenêtre a été ouverte sur une extension de Safari.

Comme tous ces événements se ressemblent, aucune extension ne peut forcer les liens provenant de l'extérieur de Safari à s'ouvrir dans de nouvelles fenêtres sans que cela n'affecte également les liens ouverts d'autres manières (y compris lors de la navigation dans Safari).

Bien qu'il ne s'ouvre pas nativement dans la fenêtre souhaitée, vous pouvez toujours saisir l'onglet et le repositionner dans une autre fenêtre Safari directement après son ouverture.

Je ne sais pas si cela peut aider ou non, juste une suggestion.