Comment supprimer toutes les conversations en une seule fois dans iMessage ?

Apple a supprimé de nombreux raccourcis clavier et fonctionnalités AppleScript dans Messages pour Big Sur. Après beaucoup d'expérimentation, j'ai conçu un AppleScript qui supprime toutes les conversations en un seul clic.

# In order to use this script, first open Settings->Keyboard->Shortcuts
# and check "Use keyboard navigation to move focus between controls"

activate application "Messages"

display dialog "Delete all messages?" buttons {"Cancel", "Delete All"} default button 2

tell application "Messages"
    set chatCount to (count of chats)
end tell

tell application "System Events"
    tell process "Messages"
        set frontmost to true
        repeat chatCount times
            # What appears as É below is actually the Ellipsis (3 dots) character, make sure
            # sure it is the correct character in Script Editor
            click menu item "Delete ConversationÉ" of menu "File" of menu bar 1
            delay 1
            # A confirmation dialog box appears, but it is hard to control:
            # - Keystroke "d" using command down NO LONGER WORKS
            # - click button "Delete" in window 1 and similar DO NOT WORK
            # What works: Move focus to "Delete" button and spacebar to click
            key code 48 # tab
            key code 49 # space
            delay 1
            # But now no conversations are selected, so
            click menu item "Go to Next Conversation" of menu "Window" of menu bar 1
            delay 1
        end repeat
    end tell
end tell

Ce code peut être cloné à partir de https://gitlab.com/HenryKautz/OSXMessagesDeleteAll