Trier les contacts marqués comme société

Question

Trier les contacts marqués comme société

Demandé el 26 de Janvier, 2015: Quand la question a-t-elle été
208 affichage: Nombre de visites la question a
1 Réponses: Nombre de réponses aux questions
Résolu: Situation réelle de la question

J'ai trouvé un Applescript à site d'assistance d'apple pour classer tout contact dont la case "Société" est cochée dans un groupe "Entreprise" :

property groupName : "Business"
tell application "Contacts"
    if (name of groups as list) does not contain groupName then
        make new group at end of groups with properties {name:groupName}
    end if
    repeat with singlePerson in people
        if company of singlePerson is true then
            if (people of group groupName as list) does not contain (singlePerson as list) then
                make new person at end of group groupName with data singlePerson
            end if
        end if
    end repeat
    save
end tell

Il échoue sur :

            make new person at end of group groupName with data singlePerson

Avec une erreur :

error "Contacts got an error: AppleEvent handler failed." number -10000

Quelqu'un connaît-il une méthode permettant de trier tous les contacts cochés comme "Entreprise" ?

Par exemple, je ne veux PAS d'une personne qui porte le nom d'une entreprise mais qui est une carte individuelle :

enter image description here

Mais je veux vraiment des entreprises qui ont Company cochée :

enter image description here

Demandé el 26 de Janvier, 2015 par Adrian

Answer 1

1 Réponses

Answer 2

2voto

markhunte Points 11634

Mise à jour :

Je pensais à l'origine que tu n'avais pas besoin d'Applescript pour faire ça.

Et vous pouvez créer un groupe intelligent qui le fait pour vous.

enter image description here

MAIS L'option "Company : is set" n'est pas destinée à la case à cocher. C'est pour le champ de texte "Société".

Vous ne pouvez donc pas utiliser la méthode ci-dessus dans ce cas, car elle ne se soucie pas de savoir si la case à cocher de la société est cochée ou non. Il ne se soucie que de la présence de texte dans le champ "Société".

Donc Applescript EST la solution. Et en utilisant company is true qui fait référence à la case à cocher.

    property groupName : "Business"
tell application "Contacts"

    if not (exists (group groupName)) then
        make new group with properties {name:groupName}
    end if
    set the_people to people whose company is true
    repeat with i from 1 to number of items in the_people
        set this_person to item i of the_people
        add this_person to group groupName
        save
    end repeat
end tell

Répondu el 26 de Janvier, 2015 par markhunte (11634 Points )

Trier les contacts marqués comme société

Réponse

Questions en vedette

Top Tags

LesApples.com

Powered by:

Trier les contacts marqués comme société

Réponse

Questions en vedette

Top Tags

Dans notre réseau

LesApples.com

Powered by: