Comment sortir les résultats d'un redimensionnement d'image AppleScript script et les afficher dans automator.

Essayez ceci :

use scripting additions

global target_width
global selImgs, chgList -- list of selected images, list of scaled images
global ctr, imgCt -- processed image counter, progress bar image total

set selImgs to {}
set target_width to 2000
set chgList to {}

display dialog "Enter maximum width" default answer "2000"
set target_width to the text returned of result as integer

-- Close scaled list (if open from previous run)
tell application "TextEdit"
    if exists document "scaled.txt" then
        close document "scaled.txt"
    end if
end tell

-- Selected images > list of alias
tell application "Finder"
    set selImgs to selection as alias list
end tell

-- construct progress bar
set imgCt to length of selImgs
set my progress total steps to imgCt
set my progress completed steps to 0
set ctr to 0
set my progress description to "Scaling images..."
set my progress additional description to "Preparing to process."

-- the horror…
repeat with ei in selImgs
    rescale_and_save(ei)
end repeat

-- Notification of changes (filenames if < 4, otherwise count)
considering application responses
    set AppleScript's text item delimiters to space
    if length of chgList > 4 then
        set imChg to length of chgList as text
    else
        set imChg to chgList as text
    end if
    display notification imChg with title "Images scaled"
end considering

-- Publish list of scaled images
set AppleScript's text item delimiters to return
set chText to chgList as text
set scFile to (((path to desktop) as text) & "scaled.txt") as «class furl»
close access (open for access scFile)
write chText to scFile as text
tell application "TextEdit"
    open scFile
    set bounds of front window to {30, 30, 300, 240}
end tell

-- the horror….
to rescale_and_save(this_file)
    tell application "Image Events"
        launch
        -- before each test run, I duplicate the images, so I won't have to re-fetch the originals
        if name of this_file contains "copy" then

            -- open the image file, increment progress bar
            set this_image to open this_file
            set ctr to (my progress completed steps) + 1
            set my progress additional description to "Scaling image " & ctr & " of " & imgCt
            set my progress completed steps to ctr

            -- process image (measure, scale, save, collect name)
            copy dimensions of this_image to {current_width, current_height}

            if current_width is greater than target_width then -- wide enough to process
                set txName to name of this_image as text

                if current_width is greater than current_height then -- when landscape
                    scale this_image to size target_width
                    save this_image with icon
                    copy txName to end of chgList

                else -- when portrait
                    -- figure out new height
                    -- y2 = (y1 * x2) / x1

                    -- NB as 'scale to size' requires integer, round up
                    set new_height to round (current_height * target_width / current_width) rounding up
                    scale this_image to size new_height
                    save this_image with icon
                    copy txName to end of chgList
                end if
            end if
            close this_image
        end if
    end tell

end rescale_and_save

Notes :

• Pour boucler les fichiers, il est plus simple de faire some_items une liste d'alias

• Lors de la mise à l'échelle avec size plutôt que factor , new_height devrait être un nombre entier

• Sauver dans if…then sinon tous les fichiers sélectionnés seront réenregistrés, même s'ils ne sont pas mis à l'échelle.

• Utilisez Image Events pour enregistrer les fichiers

• Si votre dossier est un sous-dossier de Pictures, vous pouvez activer la fonction "Dimensions" dans la vue en liste, qui affiche quelque chose comme "2097 ×". 3014", ce qui vous permet de voir quelles images seront mises à l'échelle. L'affichage n'est pas rapidement, de sorte qu'il n'affiche généralement pas la nouvelle dimension, à la place, il affiche "--", ce qui a au moins le mérite de d'identifier les fichiers qui ont été modifiés.

• Barre de progression

• Suivi des images mises à l'échelle et émission d'une notification lorsque cela est fait, ainsi que création d'un fichier texte sur le bureau.

• Facultatif : Faites un essai script - teste les dimensions de chaque image et renvoie un rapport (par exemple, le nombre d'images à mettre à l'échelle, les noms de fichiers des images à mettre à l'échelle). images à mettre à l'échelle). Vous pourriez même faire en sorte que la sélection ne porte que sur les fichiers du Finder une fois terminée. Ensuite, lorsque vous exécutez la commande script final, il sera clair quels fichiers seront modifiés.

Pour info, j'ai essayé d'utiliser factor à l'échelle, mais j'ai trouvé qu'après avoir fonctionné pendant un certain temps, il devenait erratique, et bloquait souvent le script (et faisait surchauffer mon mac, et m'obligeait à quitter manuellement sips). Je me suis lassé de cela et j'ai utilisé size (mais avec un forçage new_height pour être un nombre entier). Après ce changement, il est devenu plus fiable. Vous pouvez trouver le suivi inutile.