Comment désactiver ce message : "le disque n'a pas été éjecté correctement" ?

Cet applescript les fermera pour vous. Collez-le dans l'éditeur script, puis enregistrez-le comme application. Accordez ensuite l'accès à cette application dans (Préférences système > Sécurité et confidentialité > Accessibilité). Vous pouvez alors utiliser une application comme ControlPlane https://www.controlplaneapp.com/ pour exécuter l'application sur le réveil, ce qui les ferme tous automatiquement ! ** Remarque : vous devrez également accorder l'accès à l'accessibilité à ControlPlane.

tell application "System Events"
tell process "NotificationCenter"
    set numwins to (count windows)
    repeat with i from numwins to 1 by -1
        tell window i
            set temp to value of static text 1
        end tell
        if temp contains "Disk Not Ejected Properly" then
            click button "Close" of window i
        end if
    end repeat
end tell
end tell

Ce n'est certainement pas une réponse élégante mais vous pouvez désactiver UserNotificationCenter.app qui se trouve dans /system/library/coreservices - remplacez-la par une autre application ou un fichier du même nom. Cela empêchera tous les avertissements d'apparaître (y compris le fait que votre disque est plein), alors faites attention à cela, mais d'après mon expérience, cela fait ce que vous recherchez.

En fait, j'ai fait ça à mon Mac il y a longtemps, et j'ai oublié jusqu'à ce que vous posiez votre question. Crédit : Macpadawon à http://macosx.com/forums/mac-os-x-system-mac-software/297194-disable-device-removal-message.html pour la réponse - au même endroit où j'ai trouvé ma réponse il y a quelques années.

Fonctionne avec MacOS Big Sur

Cet AppleScript désactive toutes les notifications concernant l'éjection incorrecte du disque.

tell application "System Events"
    tell process "Notification Center"
        set group_index to 1
        repeat
            try
                set the_window to group group_index of UI element 1 of scroll area 1 of window "Notification Center"
                set notification to value of static text of the_window
                set notification_title to item 1 of notification
                if notification_title = "DISK NOT EJECTED PROPERLY" then
                    set the_actions to actions of the_window
                    repeat with the_action in the_actions
                        if description of the_action is "Close" then
                            tell the_window
                                perform the_action
                            end tell
                        end if
                    end repeat
                    # Wait for the notification to disappear so that the indexes of the remaining notifications are updated accordingly.
                    delay 0.25
                    # Do not increment `group_index` because all remaining notifications have their index decremented by 1 since this notification was dismissed. We do not need to worry about the notifications before the one just dismissed because we already know that they are not notifications about disk ejection.
                else
                    # This is not a disk ejection notification, so skip it and look at the next notification.
                    set group_index to group_index + 1
                end if
            on error error_message
                # There are no more notifications to process.
                exit repeat
            end try
        end repeat
    end tell
end tell

Vous pouvez exécuter cet AppleScript toutes les 10 secondes avec la PLIST launchd ci-dessous. Veillez à le modifier pour qu'il fonctionne avec votre propre configuration. Placez ensuite la PLIST dans ~/Library/LaunchAgents et exécuter launchctl load ~/Library/LaunchAgents/file.plist (remplacement file.plist avec le nom du fichier) dans le Terminal.

Ce qui est vraiment cool avec launchd, c'est que si une tâche ne s'exécute pas parce que l'ordinateur est endormi (par exemple, lorsque votre ordinateur portable est fermé), launchd l'exécutera dès que l'ordinateur se réveillera (et si la tâche était censée s'exécuter plusieurs fois pendant que l'ordinateur était endormi, les exécutions multiples seront regroupées en une seule au réveil). Ceci est vraiment utile pour débrancher un ordinateur portable fermé d'une station d'accueil avec un disque dur attaché et ensuite utiliser l'ordinateur portable en déplacement.

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
  <dict>
    <key>Label</key>
    <string>com.YourName.DismissNotifications</string>
    <key>ProgramArguments</key>
    <array>
      <string>osascript</string>
      <string>/path/to/script</string>
    </array>
    <key>RunAtLoad</key>
    <true/>
    <key>StartInterval</key>
    <integer>10</integer>
  </dict>
</plist>

UPDATE !

OMG ! QuantumG est un génie ! Voici un hack ( et je veux dire un vrai hack de la vie ) pour désactiver uniquement ce message ennuyeux et laisser le reste du système de notification intact...

http://quantumg.blogspot.com/2015/04/disabling-os-x-device-removal-warnings.html

Avertissement : Ceci est une astuce de pro et n'est pas pour les âmes sensibles ! Il faut pirater les fichiers système de Mac OSX et vous risquez de casser votre Mac.

Modifié pour plus de clarté.

Le problème avec les lecteurs flash ou autres lecteurs USB est le suivant : lorsque vous écrivez des données sur un lecteur... N'IMPORTE QUEL disque de votre système, les données sont d'abord écrites dans un tampon en mémoire. Plus tard, lorsque l'ordinateur s'en occupera, il videra les tampons sur le périphérique (disque dur, SSD ou tout autre périphérique USB). Cette opération peut être instantanée (du moins pour nous, simples mortels) ou prendre quelques secondes. Le délai possible signifie que si vous retirez un périphérique USB avant que les tampons n'aient été vidés, vous pouvez vous retrouver avec un disque corrompu ou un ensemble de fichiers corrompus sur le disque.

Si vous ne lisez qu'à partir d'un périphérique, il n'est PAS NÉCESSAIRE de vider les tampons d'écriture avant de tirer sur votre cœur, car ils sont vides et n'ont pas besoin d'être vidés sur le périphérique.

Donc... L'avertissement ennuyeux de MAC OS X n'est probablement PAS pertinent. Il n'est important de le faire que si vous avez récemment écrit sur le périphérique, et que vous ne lui avez pas laissé suffisamment de temps pour vider les tampons (quelques secondes, maximum). Il n'est JAMAIS nécessaire d'attendre que les tampons soient vidés si vous ne faites que lire sur le périphérique USB.

Par conséquent, Apple BESOIN de fournir un moyen de désactiver les messages individuels pour les utilisateurs expérimentés. Ne traitez pas tout le monde comme un n00b à qui on ne peut pas faire confiance pour savoir comment fonctionne son ordinateur.

Et ceux qui se plaignent que j'ai tort et qu'il existe un moyen de désactiver les messages en désactivant TOUT LE SOUS-SYSTÈME DE NOTIFICATION ont tout simplement tort. Désactiver l'ensemble du sous-système de notification n'est pas une solution acceptable, tout comme retirer la batterie de votre téléphone portable n'est PAS une solution acceptable pour recevoir trop d'appels de télémarketing. Le sous-système de notification est important et ne devrait pas être désactivé simplement parce que le PO trouve qu'un des nombreux messages est ennuyeux.

Il s'agit d'un problème qui ne peut être résolu de manière adéquate que si Apple fournit aux utilisateurs un moyen de refuser des messages spécifiques.