Conformément aux informations dans le message original et aux commentaires, ceci sera fait comme demandé.

Dans Automator:

• Créez un nouveau Workflow.
• Ajoutez une action Rechercher des éléments du Finder .
  • Avec les paramètres, par exemple, Recherche (Documents)
  • (Tout) des éléments suivants sont vrais
  • (Type) (est) (PDF)

• Ajoutez une action Exécuter un script Apple .

  • Remplacez le code par défaut par le code AppleScript exemple suivant affiché ci-dessous:

  • Note: Si Skim n'est pas dans le dossier /Applications, alors modifiez la valeur de la skimpdfPathFilename variable en conséquence. Vous ne devriez pas avoir besoin de modifier autre chose sauf si vous voulez définir la valeur de la offsetInSeconds variable, par exemple définir offsetInSeconds à 60, à une autre valeur. Cette variable est utilisée pour aider à trouver les fichiers qui ont vraiment été modifiés depuis leur création. La différence de granularité entre la date de création et la date de modification lorsqu'un fichier est créé peut être de 0 secondes à une valeur plus élevée, qui n'est pas une valeur constante en fonction de la façon dont le fichier a été créé. Faites les ajustements nécessaires pour votre cas d'utilisation.

Ce que le Workflow et le code AppleScript exemple font:

• Recherche tous les fichiers PDF dans le dossier cible, y compris tous les sous-dossiers.
  • Cela se fait avec l'action Rechercher des éléments du Finder et sa sortie est transmise à l'action Exécuter un script Apple.
• Crée une liste de tous les fichiers PDF qui ont été modifiés après la date de création, en fonction de la valeur de la offsetInSeconds variable.
  • Cela se fait dans la première répétition boucle. Les fichiers répondant aux critères sont stockés dans modifiedFilesList pour être utilisés dans la prochaine répétition boucle.
• Crée une liste de tous les fichiers pour lesquels des annotations ont été faites dans Skim.
  • Cela se fait en utilisant xattr pour récupérer les attributs étendus des fichiers cibles. Si un fichier possède les attributs étendus cibles, un drapeau est défini sur true et s'il ne l'a pas, il est défini sur false. Les fichiers marqués comme true vont dans annotatedSkimFilesList pour être utilisés dans la prochaine répétition boucle.
• Intègre les annotations effectuées sur les fichiers dans Skim.
  • En utilisant l'utilitaire skimpdf dans Skim sur les fichiers dans annotatedSkimFilesList, les annotations sont intégrées sur place. Ainsi, pas besoin d'exporter vers un deuxième fichier, puis de supprimer l'original et de le remplacer.

REMARQUE: Bien que j'ai testé ceci et qu'il fonctionne sans problème pour moi, ne l'exécutez pas avant d'être sûr d'avoir une sauvegarde appropriée! Vous devriez également tester le flux de travail sur un petit échantillon de fichiers copiés placés en dehors du dossier de recherche réel sur lequel le flux de travail sera exécuté après que les tests sont effectués.

Exemple code AppleScript exemple :

on run {input, parameters}

    set skimpdfPathFilename to "'/Applications/Skim.app/Contents/SharedSupport/skimpdf'"

    set offsetInSeconds to 60       
    set modifiedFilesList to {}
    set annotatedSkimFilesList to {}

    repeat with i from 1 to count input
        set fileInfo to info for item i of input
        set cDate to creation date in fileInfo
        set mDate to modification date in fileInfo
        if mDate > (cDate + offsetInSeconds) then
            set end of modifiedFilesList to POSIX path of item i of input
        end if
    end repeat

    repeat with i from 1 to count modifiedFilesList
        set withNotes to (do shell script "xattr " & quoted form of item i in modifiedFilesList ¬
            & " | [ $(grep -c \".*_notes$\") -ge 1 ] && printf 'true' || printf 'false'") as boolean
        if withNotes then
            set end of annotatedSkimFilesList to item i in modifiedFilesList
        end if
    end repeat

    repeat with i from 1 to count annotatedSkimFilesList
        do shell script skimpdfPathFilename & space & "embed" & space & ¬
            quoted form of item i in annotatedSkimFilesList
    end repeat

end run

Compréhension de la do shell script commande dans la deuxième répétition boucle:

Lorsqu'un PDF est annoté dans Skim et enregistré, des attributs étendus sont définis sur le fichier, par exemple:

$ xattr NomDuFichier.pdf 
com.apple.FinderInfo
net_sourceforge_skim-app_notes
net_sourceforge_skim-app_rtf_notes
net_sourceforge_skim-app_text_notes
$ 

La sortie est pipée | vers:

[ $(grep -c \".*_notes$\") -ge 1 ] && printf 'true' || printf 'false'

Cela teste la sortie de grep en comptant les occurrences du patron et si grep trouve une ou plusieurs occurrences du patron, alors la valeur de la withNotes variable est définie sur true, tandis qu'elle est définie sur false sinon.

Remarquez que Skim a un utilitaire en ligne de commande intégré, par exemple /Applications/Skim.app/Contents/SharedSupport/skimnotes qui peut être utilisé pour tester si un PDF contient des annotations faites dans Skim, cependant en raison de sa sortie cet utilitaire est mieux utilisé dans un script shell exécuté dans Terminal puis une do shell script commande, et c'est pourquoi j'ai utilisé xattr et grep à la place.

Note: Le code AppleScript exemple ci-dessus est simplement cela, et ne comprend pas de gestion des erreurs comme cela peut être approprié/nécessaire/souhaité, la responsabilité incombe à l'utilisateur d'ajouter toute gestion des erreurs appropriée pour tout code exemple présenté et/ou code écrit par l'utilisateur lui-même.