Application AppleScript en tant que page Web Safari

Comme l'ont fait remarquer d'autres utilisateurs, les troisième et quatrième points ne valent probablement pas la peine d'être conservés, car ils rendent les deux premiers difficiles à mettre en œuvre :

use S : application "Safari"
property PHPMyAdminURL : "http://xxxxx/ppmya"

on run
    if S is not running then return openPHPMyAdmin()

    set _T to a reference to (every tab of every window of S whose ¬
        name contains "PHPMyAdmin" and ¬
        URL contains "/ppmya")

    if (count _T) > 0 then return viewPHPMyAdmin(_T)

    openPHPMyAdmin()
end run

to openPHPMyAdmin()
    tell S
        if (count windows) = 0 then
            make new document with properties ¬
                {URL:PHPMyAdminURL}
        else
            make new tab at end of tabs of S's window 1 ¬
                with properties ¬
                {URL:PHPMyAdminURL}
            set current tab of S's window 1 to the result
        end if

        activate
    end tell
end openPHPMyAdmin

to viewPHPMyAdmin(T)
    set [T] to T
    set W to the first window of S whose tabs contains T

    set current tab of W to T
    activate S
    set the index of W to 1
end viewPHPMyAdmin

Après un premier retour de l'utilisateur @3439894, j'ai supprimé l'option on quit car la tentative d'utilisation du script comme application stay-open empêche la mise en œuvre effective du point 2.