Faire en sorte que Safari charge des onglets en arrière-plan

Je ne connais aucun moyen de modifier le comportement par défaut de Safari, mais cette tâche peut être automatisée assez facilement si vous disposez d'un moyen d'exécuter un AppleScript.

J'utilise FastScripts y Maestro du clavier afin que je puisse attribuer des raccourcis clavier globaux ou spécifiques à mes nombreux scripts.

Cet AppleScript recharge tous les onglets de la fenêtre principale de Safari.

----------------------------------------------------------------
# Auth: Christopher Stone
# dCre: 2011/08/09 20:33
# dMod: 2015/11/14 16:46
# Appl: Safari
# Task: Reload Every Tab in front window.
# Libs: ELb
# Osax: None
# Tags: @Applescript, @Safari, @Reload, @Tabs, @Front, @Window
----------------------------------------------------------------

try

   tell application "Safari"

      set tabList to tabs of front window

      repeat with theTab in tabList
         tell theTab to do JavaScript "location.reload(true)"
      end repeat

   end tell

on error e number n
   stdErr(e, n, true, true) of me
end try

----------------------------------------------------------------
--» HANDLERS
----------------------------------------------------------------
on stdErr(e, n, beepFlag, ddFlag)
   set e to e & return & return & "Num: " & n
   if beepFlag = true then
      beep
   end if
   if ddFlag = true then
      if n  -128 then
         try
            tell application (path to frontmost application as text) to set ddButton to button returned of ¬
               (display dialog e with title "ERROR!" buttons {"Copy Error Message", "Cancel", "OK"} ¬
                  default button "OK" giving up after 30)
            if ddButton = "Copy Error Message" then set the clipboard to e
         end try
      end if
   else
      return e
   end if
end stdErr
----------------------------------------------------------------

Sur mon système, je lui ai donné le raccourci clavier suivant R ce qui est un bon moyen mnémotechnique pour moi.

Il est assez facile de modifier le script pour recharger chaque onglet dans chaque fenêtre.

----------------------------------------------------------------------------
# Auth: Christopher Stone
# dCre: 2011/08/09 20:33
# dMod: 2011/08/09 20:57
# Appl: Safari
# Task: Reload Every Tab in Every Window.
# Libs: None
# Osax: None
# Tags: @Applescript, @Reload, @Tabs, @Every, @Window
----------------------------------------------------------------------------

tell application "Safari"

    set tabList to tabs of windows

    repeat with theWindow in tabList
        repeat with theTab in theWindow
            tell (theTab's contents)
                do JavaScript "location.reload(true)"
            end tell
        end repeat
    end repeat

end tell

----------------------------------------------------------------------------

Je l'utilise si rarement que je ne lui ai pas donné de raccourci clavier et que je dois l'activer manuellement à partir du menu FastScripts. (Il s'agit également d'une mesure de protection qui m'évite d'appuyer sur un raccourci clavier par accident et de devoir attendre que tous les onglets se rechargent).

-ccs