Clic-droit pour créer un nouveau document - Comment?

Voici un AppleScript que j'utilise en tant qu'application AppleScript pour lui assigner l'icône de TextEdit et le placer dans la Barre d'outils du Finder. Il est alors disponible pour créer un nouveau document texte à l'emplacement actuel du Finder, pour lequel on a les permissions d'écriture. En d'autres termes, si on tente de créer un nouveau document texte à un emplacement dont l'accès en écriture est limité par exemple à root ou n'importe quel autre emplacement pour lequel on n'a pas les permissions spécifiques, on est notifié lors de la tentative de création du nouveau document.

Le code vérifie si un fichier du même nom existe déjà et le cas échéant notifie et affiche la boîte de dialogue Enregistrer sous:.

Ouvrez Éditeur AppleScript et copiez-collez le code ci-dessous dans la fenêtre vide, puis enregistrez-le en tant que Créer un nouveau fichier texte ici.app. Assurez-vous de sélectionner Application pour Format du fichier: dans la boîte de dialogue Enregistrer sous:.

Avant de l'ajouter à la Barre d'outils du Finder, vous voudrez changer son icône pour celle utilisée par TextEdit. Vous pouvez ouvrir la Fiche d'informations pour chaque application, puis copier-coller celle de TextEdit.app dans celle de Créer un nouveau fichier texte ici.app. Notez que c'est l'icône affichée dans le coin supérieur gauche de la Fiche d'informations.

Maintenant qu'il a une icône plus jolie, faites glisser et déposez la nouvelle application à l'emplacement de la Barre d'outils du Finder où vous souhaitez qu'elle soit. Notez que selon la version d'OS X / macOS, vous pourriez devoir appuyer sur la touche Commande tout en faisant glisser l'application vers la Barre d'outils du Finder.

Pour l'utiliser, cliquez simplement sur l'icône Créer un nouveau fichier texte ici.app dans la Barre d'outils du Finder, et vous serez invité à donner un nom pour qu'un nouveau document texte soit créé et ouvert à l'emplacement actuel de la Fenêtre de Finder.

on run
    my createNewTextFile()
end run

on createNewTextFile()

    tell application "Finder"
        activate
        set the currentFolder to (folder of the front window as alias)
    end tell

    tell me
        activate
        set fileName to ""
        repeat while fileName = ""
            display dialog "Enregistrer sous:" with title "Créer un nouveau fichier texte ici" default answer fileName buttons {"Annuler", "OK"} default button 2
            set fileName to text returned of the result
        end repeat
        if fileName ends with ".txt" then
            set newTextFile to POSIX path of currentFolder & fileName
        else
            set newTextFile to POSIX path of currentFolder & fileName & ".txt"
        end if

    end tell

    tell application "Finder"
        set itExists to (exists newTextFile as POSIX file)
    end tell

    tell me
        activate
        if itExists is false then
            try
                do shell script "touch \"" & newTextFile & "\"; open \"" & newTextFile & "\""
            on error
                display dialog "Impossible de créer le fichier \"" & newTextFile & "\" à cet emplacement!..." with title "Impossible de créer le fichier" buttons {"OK"} default button 1 with icon stop
            end try
        else
            display dialog "Le fichier \"" & newTextFile & "\" existe déjà!..." with title "Fichier déjà existant" buttons {"OK"} default button 1 giving up after 5
            my createNewTextFile()
        end if
    end tell

end createNewTextFile

Notez que ce code pourrait également être utilisé dans Automator pour un flux de travail de Service, cependant j'ai constaté que je suis déjà dans Finder lorsque je veux créer un nouveau document texte et il est plus facile de cliquer sur l'icône Créer un nouveau fichier texte ici.app dans la Barre d'outils du Finder que de faire un clic droit et de choisir parmi le menu contextuel des Services déjà surchargé que j'ai.

De plus, si vous modifiez le code une fois que le script est enregistré en tant qu'application et placé dans la Barre d'outils du Finder, alors vous devrez supprimer l'icône de la Barre d'outils et ensuite faire glisser et déposer le nouveau Créer un nouveau fichier texte ici.app enregistré pour qu'il fonctionne correctement.