Comment faire pour que mon traducteur binaire traite plusieurs nombres binaires

Votre script peut être grandement simplifié. Ce que vous semblez faire, c'est convertir un nombre binaire en base 10 (décimale), puis à partir de là en un code de caractère. (Note latérale : Il est toujours utile d'essayer d'être explicite dans la description de ce que votre code fait - ou a l'intention de faire.)

set bits to every character in the text returned of ¬
    (display dialog "Entrée binaire :" with icon note ¬
    buttons {"Annuler", "Convertir"} default button 2 ¬
    with title "Conversion binaire en texte")

set |2| to 1 -- puissances de 2, c'est-à-dire 2, 2¹, 2², 2³,..., 2
set d to 0    -- la valeur en base 10 (remplace votre chaîne décimale)

repeat with bit in the reverse of the bits
    set d to d + bit * |2|
    set |2| to 2 * |2|
end repeat

set char to character id d
return char

Vous souhaitez répéter ce processus plusieurs fois pour convertir autant de nombres binaires que l'utilisateur en fournit. Il n'y a pas beaucoup d'options pour permettre facilement à l'utilisateur d'obtenir plusieurs valeurs. Mais il semble que vous expérimentez avec le codage binaire/texte des données, et que ces nombres binaires représentent probablement 8 bits d'un seul octet de données, donc il semble raisonnable de laisser un utilisateur fournir autant de bytes de données qu'il souhaite dans une boîte de dialogue d'entrée unique, en séparant simplement chaque valeur binaire par un espace, par exemple

"1011010 11010011 01011000 ..."

ce qui représenterait trois bytes de données sous forme binaire qui sont faciles à diviser en éléments individuels et à convertir un par un.

Pour ce faire, il est logique de placer le morceau de code qui effectue la conversion de base à l'intérieur d'un handler (fonction) qui peut être réutilisé encore et encore pour effectuer autant de conversions que nécessaire sans avoir à réécrire le code identique à chaque fois.

Voici un brouillon d'un script qui fait tout cela:

set bytes to every word in the text returned of ¬
    (display dialog "Entrée binaire :" with icon note ¬
    buttons {"Annuler", "Convertir"} default button 2 ¬
    with title "Conversion binaire en texte")

set chars to {} -- cela se remplira avec chaque conversion décimale

repeat with bits in bytes
     -- appeler le handler ci-dessous
    set end of chars to the decimal from bits
end repeat

-- Maintenant convertir les nombres décimaux en texte
return character id chars

# Un handler qui prend un nombre binaire et renvoie sa représentation
# décimale. La valeur binaire peut être transmise de l'une des
# manières suivantes:
#        1. une liste de caractères de nombres
#             par exemple {0, 1, 0, 1, 1, 0, 1, 0}, ou
#                  {"0", "1", "0", "1", "1", "0", "1", "0"}  
#        2. une chaîne, par exemple "01011010"
#        3. un nombre, par exemple 1011010
to decimal from binary as {list, text, integer}
    local binary

    set |2| to 1
    set d to 0

    tell a reference to binary to if its class  list then ¬
        set the contents to the characters of (it as text)

    repeat with bit in the reverse of the binary
        set d to d + bit * |2|
        set |2| to 2 * |2|
    end repeat

    return d
end decimal