AppleScript pour renommer les noms de fichiers

La méthode native d'Applescript pour renommer des fichiers est la suivante :

tell application "Finder"
    set theFile to (choose file)
    set name of theFile to "Yay"
end tell

Si vous vouliez renommer tous les fichiers d'un dossier, je mettrais les fichiers dans une liste et j'utiliserais une méthode de renom. Repeat sur chacun d'eux :

tell application "Finder"
    set theFolder to (choose folder)
    set folderContents to every item of theFolder
    repeat with theFile in folderContents
        set name of theFile to "Yay"
    end repeat
end tell

(Ce code ne s'exécutera pas tel quel car vous ne pouvez pas avoir deux fichiers nommés "Yay", mais le premier est renommé, et vous comprenez l'idée).

C'est plus proche de ce que vous voulez faire, mais nous n'en sommes pas encore là : vous voulez obtenir le nom du fichier actuel, y apporter quelques modifications et enregistrer le nouveau nom.

Il y a une sous-routine que j'ai trouvée il y a des années quelque part (je n'arrive pas à trouver la source maintenant) qui récupère tout ce qui se trouve à droite d'un certain caractère, comme un trait de soulignement. Il est ainsi facile de faire exactement ce que vous voulez. Le code complet et final est :

tell application "Finder"
    set theFolder to (choose folder)
    set folderContents to every item of theFolder
    repeat with theFile in folderContents
        set oldName to name of theFile
        set newName to my rightString(oldName, "_")
        set name of theFile to newName
    end repeat
end tell

on rightString(str, del)
    local str, del, oldTIDs
    set oldTIDs to AppleScript's text item delimiters
    try
        set str to str as string
        if str does not contain del then return str
        set AppleScript's text item delimiters to del
        set str to str's text items 2 thru -1 as string
        set AppleScript's text item delimiters to oldTIDs
        return str
    on error eMsg number eNum
        set AppleScript's text item delimiters to oldTIDs
        error "Can't rightString: " & eMsg number eNum
    end try
end rightString

Je ne sais rien à propos d'Hazel. Cependant, le code AppleScript suivant supprimera tout ce qui se trouve à gauche du premier "_" inclus dans les noms des fichiers sélectionnés dans le Finder et renommera les fichiers sélectionnés en conséquence.

tell application "Finder"
    set theFiles to (get selection)
    repeat with i from 1 to count of theFiles
        set thisFile to item i of theFiles
        set thisName to name of thisFile
        set theOffset to my (offset of "_" in thisName)
        set newName to text (theOffset + 1) ¬
            thru -1 of thisName
        set name of thisFile to newName
    end repeat
end tell