3 votes

David avatar

Comment régler rapidement les coins chauds dans Mavericks ?

Demandé el 25 de Octobre, 2013
Quand la question a-t-elle été
3529 affichage
Nombre de visites la question a
3 Réponses
Nombre de réponses aux questions
Résolu
Situation réelle de la question

J'ai utilisé un applescript téléchargé pour activer/désactiver rapidement les coins chauds mais ils ne fonctionnent plus après la mise à jour vers Mavericks. Quelqu'un sait-il ce qui se passe ?

Voici le script désactivé, j'espère qu'il vous aidera à savoir de quoi je parle.

tell application "System Events"
    activate
    if UI elements enabled then
        tell expose preferences
            set properties of the top left screen corner to {activity:none, modifiers:{}}
            set properties of the top right screen corner to {activity:none, modifiers:{}}
            set properties of the bottom left screen corner to {activity:none, modifiers:{}}
            set properties of the bottom right screen corner to {activity:none, modifiers:{}}
        end tell
    else
        tell application "System Preferences"
            activate
            set current pane to pane "com.apple.preference.universalaccess"
            display dialog "UI element scripting is not enabled. Check \"Enable access for assistive devices\""
        end tell
    end if
end tell

tell application "System Preferences" to quit
Demandé el 25 de Octobre, 2013 par David

Réponses

Trop de publicités?

2voto

Matthieu Riegler avatar
Matthieu Riegler Points 20160

Avant Mavericks, il y avait effectivement une propriété dans System Events appelée "Expose preference".

Depuis 10.7 Lion, Expose a été remplacé par Mission Control, il doit donc s'agir d'un vestige de cette époque révolue (Le volet préfabriqué s'appelle Expose.prefPane ).

Mais dans Mavericks, cette propriété a été supprimée et non remplacée.

tell application "System Events" to get properties renvoie à

  • préférences en matière de sécurité
  • préférences du réseau
  • préférences de l'écran de veille
  • préférences en matière d'apparence
  • Préférences pour les CD et DVD
  • préférences de dock

Et aucun d'entre eux n'a accès aux propriétés du coin chaud.

Donc, non, il n'est actuellement pas possible de faire la même chose. Ou pour être plus précis, de le faire sans scripting UI. (BTW votre script n'utilise pas les fonctionnalités de scripting UI).

Répondu el 7 de Novembre, 2013 par Matthieu Riegler (20160 Points )

2voto

hekevintran avatar
hekevintran Points 228

Une solution a été publiée à l'adresse suivante https://discussions.apple.com/message/23989931 :

property theSavedValues : {"Mission Control", "Desktop", "Dashboard", "Launchpad"} -- for example

tell application "System Preferences"
    activate
    set current pane to pane id "com.apple.preference.expose"
    tell application "System Events"
        tell window "Mission Control" of process "System Preferences"
            click button "Hot Corners…"
            tell sheet 1
                tell group 1
                    set theCurrentValues to value of pop up buttons
                    if theCurrentValues is {"-", "-", "-", "-"} then
                        repeat with i from 1 to 4
                            set thisValue to item i of theSavedValues
                            tell pop up button i
                                click
                                click menu item thisValue of menu 1
                            end tell
                        end repeat
                    else
                        copy theCurrentValues to theSavedValues
                        repeat with i from 1 to 4
                            tell pop up button i
                                click
                                click last menu item of menu 1
                            end tell
                        end repeat
                    end if
                end tell
                click button "OK"
            end tell
        end tell
    end tell
    quit
end tell
Répondu el 12 de Juillet, 2014 par hekevintran (228 Points )

0voto

user637338 avatar
user637338 Points 141

Je cherchais également une réponse à cette question et je me suis finalement mis très en colère contre les développeurs d'Apple. Comme je l'ai découvert, la prise en charge des scripts pour certains volets de préférences a disparu. Cependant, j'ai découvert ce lien

Il suffit d'utiliser la méthode des touches favorites

ce qui me semble être une bonne solution. Cela ne résout pas votre problème avec les scripts, je sais, mais je dirais que c'est même la solution la plus élégante, car la meilleure ligne de code est celle qui n'a jamais été écrite, ou quelque chose comme ça.

Je peux vivre avec cette solution, j'espère que d'autres le pourront aussi.

Je poste également la solution ici, car je suis toujours en colère lorsque je trouve une solution qui fonctionne et que le lien est cassé : (Cette solution est volée à LexFriedman à http://hints.macworld.com/article.php?story=20130621130534978 )

Mais quiconque utilise les coins chauds (qu'OS X appelle indifféremment les coins actifs de l'écran) déclenche parfois accidentellement ces raccourcis contrôlés par la souris. La solution est la suivante : Lorsque vous choisissez un paramètre de coin chaud dans l'un des menus déroulants, maintenez la ou les touches de modification de votre choix enfoncées. Vous verrez les options passer de, disons, Mission Control à Option Mission Control" à la place.

À partir de ce moment-là, votre coin ne fonctionnera que si vous maintenez également enfoncée la ou les touches de modification que vous avez spécifiées. Désormais, l'accès au menu Apple ne déclenchera pas votre raccourci Coin chaud, à moins que vous n'appuyiez également sur la touche modificatrice que vous avez sélectionnée.

Répondu el 28 de Novembre, 2013 par user637338 (141 Points )

Questions en vedette

Top Tags

Dans notre réseau

LesApples.com

LesApples est une communauté de Apple où vous pouvez résoudre vos problèmes et vos doutes. Vous pouvez consulter les questions des autres utilisateurs d'appareils Apple, poser vos propres questions ou résoudre celles des autres.

Powered by:

Yandex
X