Comment sauvegarder les messages envoyés dans le même dossier que le message auquel on répond ?

Mail peut être étendu pour imiter assez fidèlement la fonctionnalité d'Outlook que vous mentionnez.

OS X fournit une fonction appelée services qui peuvent être utilisées pour étendre les fonctionnalités d'une application (voir http://www.macosxautomation.com/services/learn/index.html pour plus d'informations).

Je vais utiliser Automator et AppleScript pour créer un service qui déplace les messages envoyés vers le dossier du message auquel on répond, puis j'attribuerai le raccourci clavier standard de réponse ( R ) au service :

• Fermer le courrier.

• Ouvrir Automator dans le dossier Applications et choisissez Service :

• Sélectionnez Utilitaires sous Bibliothèque et draguer Exécuter AppleScript dans le volet vide à droite :

• Configurez le service pour qu'il ne reçoive aucune entrée dans le courrier :

• Remplacer le contenu de la Exécuter AppleScript action avec :

   on run {input, parameters}
  
   tell application "Mail"
       try
           (* Get selected messages or exit *)
           set messageSelection to selection
           set selectedMessage to item 1 of messageSelection
           set replyMessage to reply selectedMessage opening window yes
           set messageID to message id of selectedMessage
           set currentMailbox to mailbox of selectedMessage
       on error
           return
       end try
       repeat
           (* Wait until reply message is sent *)
           delay 2
           try
               if replyMessage is not visible then exit repeat
           on error
               exit repeat
           end try
       end repeat
       synchronize with (account of currentMailbox)
       (* Wait while reply message is being sent *)
       delay 10
       (* Loop over all sent messages *)
       set sentMailbox to sent mailbox of application "Mail"
       set allSentMessages to messages of sentMailbox
       repeat with sentMessage in allSentMessages
           if source of sentMessage contains messageID then
               set mailbox of sentMessage to currentMailbox
               return
           end if
       end repeat
   end tell
  
   return input
   end run

• Enregistrez avec un nom descriptif comme Répondre et déplacer un message envoyé dans le dossier actuel . Le service sera sauvegardé sur ~/Library/Services/ . Voici à quoi ressemble le service :

• Ouvrez les Préférences Système, sélectionnez l'onglet Clavier puis le volet des préférences Raccourcis clavier onglet.

• Sélectionnez Raccourcis des applications appuyez sur la touche + et changez pour l'application Mail le raccourci attribué à l'élément de menu Reply en R . Nous le changeons pour éviter les conflits lors de l'attribution de R au service ci-dessous :

• Sélectionnez Services , faites défiler jusqu'au service que vous avez précédemment ajouté et définissez le raccourci clavier sur R :

• Courrier ouvert. Remarquez que le raccourci de Reply n'est plus R mais R :

• Notez également qu'il y a un nouveau service, accessible avec R :

• Sélectionnez maintenant un message dans un dossier, appuyez sur R tapez votre réponse et envoyez-la. En quelques secondes, vous devriez voir le message envoyé apparaître dans le dossier.

Changer le service en "Répondre à tous" :

Olivier a demandé dans un commentaire comment étendre le service Automator pour répondre à l'expéditeur et aux autres destinataires :

1. Si vous utilisez une version récente de MacOS, choisissez "Action rapide" dans Automator.

2. Remplacez la ligne suivante dans l'AppleScript ci-dessus :

   set replyMessage to reply selectedMessage opening window yes

   avec :

   set replyMessage to reply selectedMessage opening window yes reply to all yes

3. Modifier le raccourci de l'application "Répondre à tous" ( shiftcommandR ) à quelque chose comme shiftoptioncommandR et lier shiftcommandR au service.

Le script a quelques limitations et effets secondaires :

• Le service ne peut pas distinguer les messages annulés des messages envoyés. Donc, si vous appuyez sur R puis changez d'avis et fermez la fenêtre, le service continuera à s'exécuter et vérifiera les ID correspondants dans votre dossier Sent.

• AppleScript n'offre aucun moyen d'obtenir une liste de réponses à un message. Ma solution consiste à obtenir l'identifiant du message auquel il est répondu et à le rechercher dans les messages envoyés.

• Le message envoyé ne peut pas être déplacé pendant son téléchargement. AppleScript ne renvoie aucun message d'erreur si c'est le cas, j'ai donc ajouté un délai de 10 secondes. Un délai de 5 secondes n'était pas fiable dans mes tests, adaptez-le à vos besoins si nécessaire.

• Pendant que le service cherche dans le dossier Sent, Mail ralentit.